Minimal models, Ext-algebras and Koszul duals

The Koszul dual of the polynomial ring $\mathbb Q$ [ $x$ ] is the exterior algebra on one odd generator. This is the enveloping algebra of the free Lie algebra on one odd generator $a$ modulo [$a$,$a$].

 i1 : R=QQ[x] o1 = R o1 : PolynomialRing i2 : L=koszulDual R o2 = L o2 : LieAlgebra i3 : describe L o3 = generators => {ko } 0 Weights => {{1, 0}} Signs => {1} ideal => { - (1/2)(ko_0 ko_0)} ambient => LieAlgebra{...10...} diff => {} Field => QQ computedDegree => 0

The Ext-algebra of $L$ is $Ext_{UL}(k,k)$, where $k$ is the coefficient field of $L$. It may be obtained using extAlgebra. A vector space basis for the Ext-algebra in positive degrees is obtained using generators(ExtAlgebra). This basis originates from the Lie generators in the minimal model, minimalModel, for which the homological degree have been raised by 1 and the signs changed.

 i4 : M=minimalModel(4,L) o4 = M o4 : LieAlgebra i5 : describe M o5 = generators => {fr , fr , fr , fr } 0 1 2 3 Weights => {{1, 0}, {2, 1}, {3, 2}, {4, 3}} Signs => {1, 1, 1, 1} ideal => {} ambient => LieAlgebra{...10...} diff => {0, (fr_0 fr_0), (fr_0 fr_1), (fr_1 fr_1) + 4 (fr_0 fr_2)} Field => QQ computedDegree => 4 map => fr => ko_0 0 fr => 0 1 fr => 0 2 fr => 0 3 source => M target => L i6 : E=extAlgebra(4,L) o6 = E o6 : ExtAlgebra i7 : gE=gens E o7 = {ext_0, ext_1, ext_2, ext_3} o7 : List i8 : weight\gE o8 = {{1, 1}, {2, 2}, {3, 3}, {4, 4}} o8 : List i9 : sign\gE o9 = {0, 0, 0, 0} o9 : List

The product in the Ext-algebra, ExtElement ExtElement, is derived by the program from the quadratic part of the differential in the minimal model. The Ext-algebra is a skew-commutative algebra. In case $L$ is the Koszul dual of a skew-commutative Koszul algebra $R$, the Ext-algebra of $L$ is equal to $R$.

 i10 : dims(4,E) o10 = | 1 0 0 0 | | 0 1 0 0 | | 0 0 1 0 | | 0 0 0 1 | 4 4 o10 : Matrix ZZ <--- ZZ i11 : ext_0 ext_0 ext_0 ext_0 o11 = 8ext_3 o11 : E

Observe that the first row of the matrix dims(4,E) gives the dimensions of $E$ in degree 1 to 5 and homological degree 1.

Here is the first known example of a non-Koszul algebra, due to Christer Lech. It is the polynomial algebra in four variables modulo five general quadratic forms, which may be specialized as follows.

 i12 : R = QQ[x,y,z,u] o12 = R o12 : PolynomialRing i13 : I = {x^2,y^2,z^2,u^2,x*y+z*u} 2 2 2 2 o13 = {x , y , z , u , x*y + z*u} o13 : List i14 : S = R/I o14 = S o14 : QuotientRing i15 : hilbertSeries(S,Order=>4) 2 o15 = 1 + 4T + 5T o15 : ZZ[T] i16 : L = koszulDual(S) o16 = L o16 : LieAlgebra i17 : E=extAlgebra(4,L) o17 = E o17 : ExtAlgebra i18 : dims(4,E) o18 = | 4 0 0 0 | | 0 5 0 0 | | 0 0 0 5 | | 0 0 0 0 | 4 4 o18 : Matrix ZZ <--- ZZ

The minimal model may also be used to compute a minimal presentation of a Lie algebra, see minimalPresentation(ZZ,LieAlgebra). Below is an example of computing a minimal presentation of the Lie algebra of strictly upper triangular 5x5-matrices. The Lie algebra is presented by means of the multiplication table of the natural basis \{$ekn;\ 1\ \le\ k\ <\ n \le\ 5$\}. The degree of $ekn$ is $n-k$. The relation [ $e14$, $e15$ ] is of degree 7 in the free Lie algebra $F$ on the basis, and the dimension of $F$ in degree 7 is 7596. To avoid a computation of the normal form of [ $e14$, $e15$ ] one uses "formal" operators. The symbol $@$ is used as formal Lie multiplication and formal multiplication by scalars, ++ is used as formal addition, and / is used as formal subtraction. Observe that $@$, like SPACE, is right associative, while / is left associative, so $a/b/c$ means $a-b-c$ and not $a-b+c$. Here is an example of a formal expression, whose normal form is 0. The normal form may be obtained by applying normalForm.

 i19 : L=lieAlgebra{a,b,c} o19 = L o19 : LieAlgebra i20 : a@b@c++3@a@c@b++2@c@b@a/2@b@c@a o20 = (a b c) + 3 (a c b) + 2 (c b a) - 2 (b c a) o20 : L i21 : normalForm oo o21 = 0 o21 : L

Here is the computation of the matrix example.

 i22 : F=lieAlgebra({e12,e23,e34,e45,e13,e24,e35,e14,e25,e15}, Weights => {1,1,1,1,2,2,2,3,3,4}) o22 = F o22 : LieAlgebra i23 : I={e12@e34,e12@e45,e23@e45,e12@e13,e12@e35,e12@e14, e12@e15,e23@e45,e23@e13,e23@e24,e23@e14,e23@e25, e23@e15,e34@e24,e34@e35,e34@e14,e34@e25,e34@e15, e45@e13,e45@e35,e45@e25,e45@e15,e13@e24,e13@e14, e13@e25,e13@e15,e24@e35,e24@e14,e24@e25,e24@e15, e35@e14,e35@e25,e35@e15,e14@e25,e14@e15,e25@e15, e12@e23/e13, e12@e24/e14, e12@e25/e15, e13@e34/e14, e13@e35/e15, e14@e45/e15, e23@e34/e24, e23@e35/e25, e24@e45/e25, e34@e45/e35} o23 = {(e12 e34), (e12 e45), (e23 e45), (e12 e13), (e12 e35), (e12 e14), (e12 ----------------------------------------------------------------------- e15), (e23 e45), (e23 e13), (e23 e24), (e23 e14), (e23 e25), (e23 e15), ----------------------------------------------------------------------- (e34 e24), (e34 e35), (e34 e14), (e34 e25), (e34 e15), (e45 e13), (e45 ----------------------------------------------------------------------- e35), (e45 e25), (e45 e15), (e13 e24), (e13 e14), (e13 e25), (e13 e15), ----------------------------------------------------------------------- (e24 e35), (e24 e14), (e24 e25), (e24 e15), (e35 e14), (e35 e25), (e35 ----------------------------------------------------------------------- e15), (e14 e25), (e14 e15), (e25 e15), (e12 e23) - e13, (e12 e24) - ----------------------------------------------------------------------- e14, (e12 e25) - e15, (e13 e34) - e14, (e13 e35) - e15, (e14 e45) - ----------------------------------------------------------------------- e15, (e23 e34) - e24, (e23 e35) - e25, (e24 e45) - e25, (e34 e45) - ----------------------------------------------------------------------- e35} o23 : List i24 : L=F/I o24 = L o24 : LieAlgebra i25 : dims(1,5,L) o25 = {4, 3, 2, 1, 0} o25 : List i26 : M=minimalPresentation(4,L) o26 = M o26 : LieAlgebra i27 : describe M o27 = generators => {e12, e23, e34, e45} Weights => {{1, 0}, {1, 0}, {1, 0}, {1, 0}} Signs => {0, 0, 0, 0} ideal => {(e45 e23), (e45 e12), (e34 e12), (e45 e45 e34), (e34 e45 e34), (e34 e34 e23), (e23 e34 e23), (e23 e23 e12), (e12 e23 e12)} ambient => LieAlgebra{...10...} diff => {} Field => QQ computedDegree => 0

Below is a differential Lie algebra, which is non-free, and where the linear part of the differential is non-zero.

 i28 : F = lieAlgebra({a,b,c,r3,r4,r42}, Weights => {{1,0},{1,0},{2,0},{3,1},{4,1},{4,2}}, Signs => {0,0,0,1,1,0}, LastWeightHomological => true) o28 = F o28 : LieAlgebra i29 : D = differentialLieAlgebra{0_F,0_F,0_F,a c,a a c,r4 - a r3} o29 = D o29 : LieAlgebra i30 : L = D/{b c - a c,a b,b r4 - a r4} o30 = L o30 : LieAlgebra i31 : M = minimalModel(5,L) o31 = M o31 : LieAlgebra i32 : describe M o32 = generators => {fr , fr , fr , fr , fr , fr , fr } 0 1 2 3 4 5 6 Weights => {{1, 0}, {1, 0}, {2, 0}, {2, 1}, {3, 1}, {3, 1}, {5, 2}} Signs => {0, 0, 0, 1, 1, 1, 0} ideal => {} ambient => LieAlgebra{...10...} diff => {0, 0, 0, (fr_1 fr_0), (fr_1 fr_2), (fr_0 fr_2), (fr_0 fr_3 fr_2) + (fr_0 fr_0 fr_4) - (fr_0 fr_1 fr_5)} Field => QQ computedDegree => 5 map => fr => a 0 fr => b 1 fr => c 2 fr => 0 3 fr => r3 4 fr => r3 5 fr => - (a r42) + (b r42) 6 source => M target => L

The homology in homological degree 0 is concentrated in first degree 1 and 2. In the general case, for a differential Lie algebra $L$, the function minimalPresentation(ZZ,LieAlgebra) gives a minimal presentation of the Lie algebra $H_0(L)$.

 i33 : HL = lieHomology L o33 = HL o33 : VectorSpace i34 : dims(5,HL) o34 = | 2 1 0 0 0 | | 0 0 0 1 1 | | 0 0 0 0 0 | | 0 0 0 0 0 | | 0 0 0 0 0 | 5 5 o34 : Matrix ZZ <--- ZZ i35 : describe minimalPresentation(3,L) o35 = generators => {a, b, c} Weights => {{1, 0}, {1, 0}, {2, 0}} Signs => {0, 0, 0} ideal => {(b a), (b c), (a c)} ambient => LieAlgebra{...10...} diff => {} Field => QQ computedDegree => 0

We now check that the homology of the minimal model $M$ is the same as for $L$.

 i36 : HM = lieHomology M o36 = HM o36 : VectorSpace i37 : dims(5,HM) o37 = | 2 1 0 0 0 | | 0 0 0 1 1 | | 0 0 0 0 0 | | 0 0 0 0 0 | | 0 0 0 0 0 | 5 5 o37 : Matrix ZZ <--- ZZ

The quasi-isomorphism \ $f:\ M\ \to\ L$ from the minimal model $M$ of $L$ to $L$ is obtained as map(M). If $L$ has no differential, then \ $f$ \ is surjective, but in general this is not true as is shown by the example below. Another example is obtained letting $L$ be a non-zero Lie algebra with zero homology, see Differential Lie algebra tutorial.

 i38 : f = map M o38 = f o38 : LieAlgebraMap i39 : dims(5,L) o39 = | 2 1 1 1 2 | | 0 0 1 3 5 | | 0 0 0 1 2 | | 0 0 0 0 0 | | 0 0 0 0 0 | 5 5 o39 : Matrix ZZ <--- ZZ i40 : image f o40 = finitely generated subalgebra of L o40 : FGLieSubAlgebra i41 : dims(5,oo) o41 = | 2 1 1 1 2 | | 0 0 1 2 4 | | 0 0 0 0 1 | | 0 0 0 0 0 | | 0 0 0 0 0 | 5 5 o41 : Matrix ZZ <--- ZZ

We check below that $H(f)$ is iso in degree (5,1).

 i42 : basis(5,1,HL) o42 = {(b a r3) - (b b r3)} o42 : List i43 : basis(5,1,HM) o43 = {(fr_1 fr_3 fr_2) + (fr_1 fr_0 fr_4) - (fr_1 fr_1 fr_5)} o43 : List i44 : f\oo o44 = {(b a r3) - (b b r3)} o44 : List