multirationalMap -- the multi-rational map defined by a list of rational maps

Synopsis

Usage:

multirationalMap Phi

multirationalMap(Phi,Y)
Inputs:
- Phi, a list of rational maps, $\{\Phi_1:X\dashrightarrow Y_1\subseteq\mathbb{P}^{s_1},\ldots,\Phi_m:X\dashrightarrow Y_m\subseteq\mathbb{P}^{s_m}\}$, all having the same source $X\subseteq \mathbb{P}^{r_1}\times\mathbb{P}^{r_2}\times\cdots\times\mathbb{P}^{r_n}$
- Y, a multi-projective variety $Y \subseteq \mathbb{P}^{s_1}\times\mathbb{P}^{s_2}\times\cdots\times\mathbb{P}^{s_m}$ (if omitted, then the product $Y_1\times\cdots \times Y_m$ is taken)
Outputs:
- a multi-rational map, the unique rational map $\Phi:X\subseteq \mathbb{P}^{r_1}\times\mathbb{P}^{r_2}\times\cdots\times\mathbb{P}^{r_n}\dashrightarrow Y \subseteq \mathbb{P}^{s_1}\times\mathbb{P}^{s_2}\times\cdots\times\mathbb{P}^{s_m}$ such that $pr_i\circ\Phi = \Phi_i$, where $pr_i:Y\subseteq \mathbb{P}^{s_1}\times\mathbb{P}^{s_2}\times\cdots\times\mathbb{P}^{s_m} \to Y_i\subseteq \mathbb{P}^{s_i}$ denotes the i-th projection

Description

i1 : R = ring PP_(ZZ/65521)^{2,1};

i2 : f = rationalMap for i to 3 list random({1,1},R);

o2 : MultihomogeneousRationalMap (rational map from PP^2 x PP^1 to PP^3)

i3 : g = rationalMap(for i to 4 list random({0,1},R),Dominant=>true);

o3 : MultihomogeneousRationalMap (dominant rational map from PP^2 x PP^1 to curve in PP^4)

i4 : h = rationalMap for i to 2 list random({1,0},R);

o4 : MultihomogeneousRationalMap (rational map from PP^2 x PP^1 to PP^2)

i5 : Phi = multirationalMap {f,g,h}

o5 = Phi

o5 : MultirationalMap (rational map from PP^2 x PP^1 to 6-dimensional subvariety of PP^3 x PP^4 x PP^2)

i6 : describe Phi -- long description

o6 = multi-rational map consisting of 3 rational maps
     source variety: PP^2 x PP^1
     target variety: 6-dimensional subvariety of PP^3 x PP^4 x PP^2 cut out by 3 hypersurfaces of multi-degree (0,1,0)
     base locus: empty subscheme of PP^2 x PP^1
     dominance: false
     image: threefold in PP^3 x PP^4 x PP^2 cut out by 14 hypersurfaces of multi-degrees (0,1,0)^3 (1,0,2)^4 (1,1,1)^6 (1,3,0)^1 
     multidegree: {3, 6, 12, 24}
     degree: 1
     degree sequence (map 1/3): [(1,1)]
     degree sequence (map 2/3): [(0,1)]
     degree sequence (map 3/3): [(1,0)]
     coefficient ring: ZZ/65521

i7 : ? Phi -- short description

o7 = multi-rational map consisting of 3 rational maps
     source variety: PP^2 x PP^1
     target variety: 6-dimensional subvariety of PP^3 x PP^4 x PP^2 cut out by 3 hypersurfaces of multi-degree (0,1,0)
     base locus: empty subscheme of PP^2 x PP^1
     dominance: false
     image: threefold in PP^3 x PP^4 x PP^2 cut out by 14 hypersurfaces of multi-degrees (0,1,0)^3 (1,0,2)^4 (1,1,1)^6 (1,3,0)^1 
     multidegree: {3, 6, 12, 24}
     degree: 1

i8 : X = projectiveVariety R;

o8 : ProjectiveVariety, PP^2 x PP^1

i9 : Phi;

o9 : MultirationalMap (morphism from X to 6-dimensional subvariety of PP^3 x PP^4 x PP^2)

i10 : Y = target Phi;

o10 : ProjectiveVariety, 6-dimensional subvariety of PP^3 x PP^4 x PP^2

i11 : Phi;

o11 : MultirationalMap (morphism from X to Y)

i12 : Z = (image multirationalMap {f,g}) ** target h;

o12 : ProjectiveVariety, 5-dimensional subvariety of PP^3 x PP^4 x PP^2

i13 : Psi = multirationalMap({f,g,h},Z)

o13 = Psi

o13 : MultirationalMap (rational map from X to Z)

i14 : assert(image Psi == image Phi)

Caveat

Be careful when you pass the target Y as input, because it must be compatible with the maps but for efficiency reasons a full check is not done automatically. See check(MultirationalMap).

Ways to use `multirationalMap` :

"multirationalMap(List)"
"multirationalMap(List,MultiprojectiveVariety)"
multirationalMap(MultiprojectiveVariety) -- identity map
multirationalMap(MultiprojectiveVariety,MultiprojectiveVariety) -- get the natural inclusion
multirationalMap(MultirationalMap,MultiprojectiveVariety) -- change the target of a multi-rational map
"multirationalMap(RationalMap)" -- see shortcuts -- Some convenient shortcuts for multi-rational maps consisting of a single rational map

For the programmer

The object multirationalMap is a method function.

multirationalMap -- the multi-rational map defined by a list of rational maps

Synopsis

Description

Caveat

See also

Ways to use multirationalMap :

For the programmer

Ways to use `multirationalMap` :