A variety is projective if it can be realized as a closed subvariety of some projective space. For an normal toric variety, this is equivalent to saying that the associated fan is the normal fan of a polytope.
Nontrivial affine varieties are not projective.
i1 : assert not isProjective affineSpace 1 |
i2 : assert not isProjective affineSpace 3 |
i3 : U = normalToricVariety ({{4,-1,0},{0,1,0}},{{0,1}}); |
i4 : assert (not isProjective U and isDegenerate U) |
Many of our favour toric varieties are projective.
i5 : assert isProjective toricProjectiveSpace 1 |
i6 : assert isProjective toricProjectiveSpace 3 |
i7 : assert isProjective hirzebruchSurface 7 |
i8 : assert isProjective smoothFanoToricVariety (3,3) |
i9 : assert isProjective normalToricVariety (id_(ZZ^3) | -id_(ZZ^3)) |
There are complete non-projective normal toric varieties.
i10 : X1 = normalToricVariety ({{1,0,0},{0,1,0},{0,0,1},{0,-1,-1},{-1,0,-1},{-2,-1,0}},{{0,1,2},{0,1,3},{1,3,4},{1,2,4},{2,4,5},{0,2,5},{0,3,5},{3,4,5}}); |
i11 : assert (isComplete X1 and not isProjective X1 and not isSmooth X1) |
i12 : X2 = normalToricVariety ({{1,0,0},{0,1,0},{0,0,1},{0,-1,2},{0,0,-1},{-1,1,-1},{-1,0,-1},{-1,-1,0}},{{0,1,2},{0,2,3},{0,3,4},{0,4,5},{0,1,5},{1,2,7},{2,3,7},{3,4,7},{4,5,6},{4,6,7},{5,6,7},{1,5,7}}); |
i13 : assert (isComplete X2 and not isProjective X2 and isSmooth X2) |
To determine if a normal toric variety is projective, we use the Gale dual vector configuration associated to the rays; see Theorem V.4.8 in Ewald's Combinatorial convexity and algebraic geometry for more information.
To avoid repeating a computation, the package caches the result in the CacheTable of the normal toric variety.