We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{10} \cup X_{6} \subset \bf{P}^7$, of degree 16, having Betti table of type [430]. For an artinian reduction $A_F$, the quadratic part of the ideal $F^\perp$ is the ideal of a line and three independant points $p_1,p_2,p_3$, and $F^\perp$ contains pencils of ideals of three points on the line and the three fixed points $p_i$. In the pencil we find an ideal of four points in a plane and two on an independant line passing though one of the four points. We construct $X_{10}$ in a pencil of quadrics in a P6, and $X_{6}$ as a complete intersection in a P5. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.
The Betti table is $\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&7&12&7&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&3&\text{.}&\text{.}\\ \text{2:}&\text{.}&3&6&3&\text{.}\\ \text{3:}&\text{.}&\text{.}&3&4&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $
i1 : kk=QQ; |
i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7]; |
i3 : P4=ideal(y0,y1,y2);--a P4 o3 : Ideal of U |
i4 : P5=ideal(y1,y2);--a P5 o4 : Ideal of U |
i5 : X2=P4+ideal(random(2,U));--a quadric 3-fold in P4 o5 : Ideal of U |
i6 : CI1223=ideal(y0)+ideal(random(2,P4),random(2,P4),random(3,X2)); --a complete intersection (1,2,2,3) that intersects P4 in X2 and X1, a P3. o6 : Ideal of U |
i7 : X10=CI1223:X2; --a reducible 3-fold X10 of degree 10 linked to the quadric threefold X2. X10 is the union of X1 and 3-fold X9 of degree 9. o7 : Ideal of U |
i8 : Z6=X10+X2;----a complete intersection (1,1,1,2,3) surface contained in X10 o8 : Ideal of U |
i9 : X6=P5+ideal(random(2,Z6),random(3,Z6));-- X6 is a complete intersection (1,1,2,3) that intersects s10 in a hyperplane section of X6 o9 : Ideal of U |
i10 : X16=intersect(X6,X10);--a 3-fold of degree 16 in P7 with betti table of type 430. X16 is the union of X6, X1 and X9 o10 : Ideal of U |
i11 : betti res X16
0 1 2 3 4
o11 = total: 1 7 12 7 1
0: 1 . . . .
1: . 4 3 . .
2: . 3 6 3 .
3: . . 3 4 .
4: . . . . 1
o11 : BettiTally
|