The BGG correspondence is an equivalence between complexes of modules over exterior algebras and complexes of coherent sheaves over projective spaces. This function takes as input a map between two free
-modules, and returns the associate map between direct sums of exterior powers of cotangent bundles. In particular, it is useful to construct the Belinson monad for a coherent sheaf.
i1 : S = ZZ/32003[x_0..x_2];
|
i2 : E = ZZ/32003[e_0..e_2, SkewCommutative=>true];
|
i3 : alphad = map(E^1,E^{2:-1},{{e_1,e_2}});
1 2
o3 : Matrix E <-- E
|
i4 : alpha = map(E^{2:-1},E^{1:-2},{{e_1},{e_2}});
2 1
o4 : Matrix E <-- E
|
i5 : alphad' = beilinson(alphad,S)
o5 = | x_0 0 -x_2 0 x_0 x_1 |
o5 : Matrix
|
i6 : alpha' = beilinson(alpha,S)
o6 = {1} | 0 |
{1} | 1 |
{1} | 0 |
{1} | -1 |
{1} | 0 |
{1} | 0 |
o6 : Matrix
|
i7 : F = prune homology(alphad',alpha')
o7 = cokernel {1} | x_1^2-x_2^2 |
{1} | x_1x_2 |
{2} | -x_0 |
3
o7 : S-module, quotient of S
|
i8 : betti F
0 1
o8 = total: 3 1
1: 2 .
2: 1 1
o8 : BettiTally
|
i9 : cohomologyTable(presentation F,E,-2,3)
-2 -1 0 1 2 3 4
o9 = 2: 7 2 . . . . .
1: . 1 2 1 . . .
0: . . . 2 7 14 23
o9 : CohomologyTally
|
As the next example, we construct the monad of the Horrock-Mumford bundle:
i10 : S = ZZ/32003[x_0..x_4];
|
i11 : E = ZZ/32003[e_0..e_4, SkewCommutative=>true];
|
i12 : alphad = map(E^5,E^{2:-2},{{e_4*e_1,e_2*e_3},{e_0*e_2,e_3*e_4},{e_1*e_3,e_4*e_0},{e_2*e_4,e_0*e_1},{e_3*e_0,e_1*e_2}})
o12 = | -e_1e_4 e_2e_3 |
| e_0e_2 e_3e_4 |
| e_1e_3 -e_0e_4 |
| e_2e_4 e_0e_1 |
| -e_0e_3 e_1e_2 |
5 2
o12 : Matrix E <-- E
|
i13 : alpha = syz alphad
o13 = {2} | e_0e_1 e_2e_3 e_0e_4 e_1e_2 -e_3e_4 |
{2} | -e_2e_4 e_1e_4 e_1e_3 e_0e_3 e_0e_2 |
2 5
o13 : Matrix E <-- E
|
i14 : alphad' = beilinson(alphad,S)
o14 = | 0 0 0 0 x_0 0 -x_2 0 -x_3 0 0 0 -x_0 -x_1 0
| x_1 0 -x_3 0 0 -x_4 0 0 0 0 0 0 0 0 0
| 0 -x_0 0 x_2 0 0 0 0 -x_4 0 0 0 0 0 -x_1
| 0 0 0 0 0 -x_0 -x_1 0 0 x_3 -x_2 -x_3 0 0 -x_4
| 0 -x_1 -x_2 0 0 0 0 x_4 0 0 -x_0 0 0 -x_3 0
-----------------------------------------------------------------------
0 0 0 0 -x_4 |
0 0 -x_0 -x_1 -x_2 |
-x_2 0 -x_3 0 0 |
0 0 0 0 0 |
0 -x_4 0 0 0 |
o14 : Matrix
|
i15 : alpha' = beilinson(alpha,S)
o15 = {1} | 0 0 0 0 -1 |
{1} | 0 0 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 -1 0 0 |
{1} | 0 1 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 0 1 0 |
{1} | 0 0 0 0 0 |
{1} | 1 0 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 1 0 0 0 0 |
{1} | 0 1 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 -1 0 0 |
{1} | 0 0 0 1 0 |
{1} | 0 0 0 0 0 |
{1} | 0 0 0 0 -1 |
{1} | 0 0 0 0 0 |
o15 : Matrix
|
i16 : F = prune homology(alphad',alpha');
|
i17 : betti res F
0 1 2 3
o17 = total: 19 35 20 2
3: 4 . . .
4: 15 35 20 .
5: . . . 2
o17 : BettiTally
|
i18 : regularity F
o18 = 5
|
i19 : cohomologyTable(presentation F,E,-6,6)
-6 -5 -4 -3 -2 -1 0 1 2 3 4 5 6 7
o19 = 4: 210 100 35 4 . . . . . . . . . .
3: . . 2 10 10 5 . . . . . . . .
2: . . . . . . 2 . . . . . . .
1: . . . . . . . 5 10 10 2 . . .
0: . . . . . . . . . 4 35 100 210 380
o19 : CohomologyTally
|