Hom -- module of homomorphisms

Synopsis

• Usage:

  Hom(M, N)

• Inputs:
  • M, a ring, an ideal, or a module,
  • N, a ring, an ideal, or a module,
• Optional inputs:
  • DegreeLimit => ..., default value null, an integer or a list, if set, stop after homomorphisms in this degree have been computed
  • MinimalGenerators => a Boolean value, default value true, whether to trim the resulting module
  • Strategy => a thing, default value null
• Outputs:
  • a module, isomorphic to $\mathrm{Hom}_R(M,N), where $M$ and $N$ are both $R$-modules

Description

i1 : R = QQ[x,y]/(y^2 - x^3);

i2 : M = image matrix{{x, y}}

o2 = image | x y |

                             1
o2 : R-module, submodule of R

i3 : H = Hom(M, M, MinimalGenerators => true)

o3 = image {-1} | x y  |
           {-1} | y x2 |

                             2
o3 : R-module, submodule of R

i4 : formation H

o4 = Hom (image | x y |, image | x y |, DegreeLimit => null)

o4 : Expression of class FunctionApplication

i5 : f0 = homomorphism H_{0}

o5 = {1} | 1 0 |
     {1} | 0 1 |

o5 : Matrix M <-- M

i6 : f1 = homomorphism H_{1}

o6 = {1} | 0 x |
     {1} | 1 0 |

o6 : Matrix M <-- M

i7 : M_0, M_1

o7 = (| x |, | y |)

o7 : Sequence

i8 : f0 M_0, f0 M_1

o8 = (| x |, | y |)

o8 : Sequence

i9 : f1 M_0, f1 M_1

o9 = (| y |, | x2 |)

o9 : Sequence

Contributors

See also

• Ext -- compute an Ext module
• formation -- recover the methods used to make a module

Menu

• adjoint -- the tensor-Hom adjunction maps
• compose -- composition as a pairing on Hom-modules
• homomorphism -- get the homomorphism from element of Hom
• homomorphism' -- get the element of Hom from a homomorphism
• Hom(Module,Matrix) -- induced map on Hom