Description
The modules
M and
N must both be
subquotient modules where M and P have the same ambient module, and N and Q have the same ambient module. If the optional argument
Verify is given, check that the result defines a well defined homomorphism.
In this example, the module K2 is mapped via g into K1, and we construct the induced map from K2 to K1.
i1 : R = ZZ/32003[x,y,z]
o1 = R
o1 : PolynomialRing
|
i2 : g1 = matrix{{x,y,z}}
o2 = | x y z |
1 3
o2 : Matrix R <-- R
|
i3 : g2 = matrix{{x^2,y^2,z^2}}
o3 = | x2 y2 z2 |
1 3
o3 : Matrix R <-- R
|
i4 : K1 = ker g1
o4 = image {1} | -y 0 -z |
{1} | x -z 0 |
{1} | 0 y x |
3
o4 : R-module, submodule of R
|
i5 : K2 = ker g2
o5 = image {2} | -y2 0 -z2 |
{2} | x2 -z2 0 |
{2} | 0 y2 x2 |
3
o5 : R-module, submodule of R
|
i6 : f = map(ambient K1, ambient K2, {{x,0,0},{0,y,0},{0,0,z}})
o6 = {1} | x 0 0 |
{1} | 0 y 0 |
{1} | 0 0 z |
3 3
o6 : Matrix R <-- R
|
i7 : h = inducedMap(K1,K2,f)
o7 = {2} | xy 0 0 |
{2} | 0 yz 0 |
{2} | 0 0 xz |
o7 : Matrix K1 <-- K2
|
If we omit the first argument, then it is understood to be the target of f, and if we omit the second argument, it is understood to be the source of f.
i8 : h1 = inducedMap(target f,K2,f)
o8 = {1} | -xy2 0 -xz2 |
{1} | x2y -yz2 0 |
{1} | 0 y2z x2z |
3
o8 : Matrix R <-- K2
|
i9 : h2 = inducedMap(,K2,f)
o9 = {1} | -xy2 0 -xz2 |
{1} | x2y -yz2 0 |
{1} | 0 y2z x2z |
3
o9 : Matrix R <-- K2
|
i10 : h1 == h2
o10 = true
|
In this example, we cannot omit the second argument, since in that case the resulting object is not a homomorphism.