inducedMap(Module,Module) -- compute the map induced by the identity

Synopsis

Function: inducedMap
Usage:

inducedMap(M,N)
Inputs:
- M, a module
- N, a module
Optional inputs:
- Degree => ..., default value null, specify the degree of a map
- Verify => ..., default value true, verify that a map is well-defined
Outputs:
- a matrix, the homomorphism M <-- N induced by the identity.

Description

The modules M and N must both be subquotient modules of the same ambient free module F. If M = M1/M2 and N = N1/N2, where M1, M2, N1, N2 are all submodules of F, then return the map induced by F --> F. If the optional argument Verify is given, check that the result defines a well defined homomorphism.

In this example, we make the inclusion map between two submodules of R^3. M is defined by two elements and N is generated by one element in M

i1 : R = ZZ/32003[x,y,z];

i2 : P = R^3;

i3 : M = image(x*P_{1}+y*P_{2} | z*P_{0})

o3 = image | 0 z |
           | x 0 |
           | y 0 |

                             3
o3 : R-module, submodule of R

i4 : N = image(x^4*P_{1} + x^3*y*P_{2} + x*y*z*P_{0})

o4 = image | xyz |
           | x4  |
           | x3y |

                             3
o4 : R-module, submodule of R

i5 : h = inducedMap(M,N)

o5 = | x3 |
     | xy |

o5 : Matrix M <-- N

i6 : source h == N

o6 = true

i7 : target h == M

o7 = true

i8 : ambient M == ambient N

o8 = true

Ways to use this method: