Macaulay2 » Documentation
Packages » Macaulay2Doc > rings > monoid > monoid(...,Variables=>...)
next | previous | forward | backward | up | index | toc

monoid(...,Variables=>...) -- specify the names of the indeterminates

Synopsis

Description

When given a list or sequence, Variables => L specifies the variables to be used as generators of the monoid.

i1 : QQ[Variables => vars(0..3)]

o1 = QQ[a..d]

o1 : PolynomialRing
i2 : QQ[Variables => x_(0,0)..x_(3,3)]

o2 = QQ[x   ..x   ]
         0,0   3,3

o2 : PolynomialRing

When given a number, Variables => n specifies number of indexed variables to create with base name provided by VariableBaseName => s, where s may be either a symbol or string. The default base name is p.

i3 : QQ[Variables => 2]

o3 = QQ[p ..p ]
         0   1

o3 : PolynomialRing
i4 : QQ[Variables => 3, VariableBaseName => v]

o4 = QQ[v ..v ]
         0   2

o4 : PolynomialRing
i5 : QQ[Variables => 4, VariableBaseName => "e"]

o5 = QQ[e ..e ]
         0   3

o5 : PolynomialRing
i6 : class baseName e_0

o6 = IndexedVariable

o6 : Type
i7 : class e

o7 = IndexedVariableTable

o7 : Type

This option is also useful when creating a new ring from an existing ring, creating a tensor product ring, or symmetric algebra.

i8 : R = QQ[x, y, Degrees => {1, 2}]

o8 = R

o8 : PolynomialRing
i9 : newRing(R, Variables => {a,b})

o9 = QQ[a..b]

o9 : PolynomialRing
i10 : degrees oo

o10 = {{1}, {2}}

o10 : List
i11 : tensor(R, R, Variables => t_(0,0)..t_(1,1))

o11 = QQ[t   ..t   ]
          0,0   1,1

o11 : PolynomialRing
i12 : degrees oo

o12 = {{1, 0}, {2, 0}, {0, 1}, {0, 2}}

o12 : List
i13 : symmetricAlgebra(R^3, Variables => s_0..s_2)

o13 = R[s ..s ]
         0   2

o13 : PolynomialRing

Further information

See also

Functions with optional argument named Variables :