Conics on a quintic threefold -- an example

The number of conics (rational curves of degree 2) on a general quintic hypersurface in $\PP^4$ was computed by S. Katz in 1985. Here is how the computation can be made with Schubert2.

Any conic in $\PP^4$ spans a unique plane, and the conics in a plane correspond to the points of $\PP^5$. Hence the space of conics in $\PP^4$ is a certain $\PP^5$-bundle $X$ over the Grassmannian $G$ of planes in $\PP^4$.

i1 : G = flagBundle{2,3}

o1 = G

o1 : a flag bundle with subquotient ranks {2..3}

We extract the rank 2 tautological subbundle $S$ and the rank 3 tautological quotient bundle $Q$:

i2 : (S,Q) = bundles G

o2 = (S, Q)

o2 : Sequence

We form the bundle of quadratic forms on the variable planes:

i3 : B = symmetricPower(2,Q)

o3 = B

o3 : an abstract sheaf of rank 6 on G

As a matter of convention, a projective bundle constructed by the function projectiveBundle' in Schubert2 parametrizes rank 1 quotients of the sheaf provided. The $\PP^5$-bundle of conics is given by sublinebundles of $B$, or equivalently, by rank 1 quotients of the dual, $B^*$, as in the following code:

i4 : X = projectiveBundle'(dual B, VariableNames => {,{z}})

o4 = X

o4 : a flag bundle with subquotient ranks {5, 1}

The equation of the general quintic is a section of the fifth symmetric power of the space of linear forms on $\PP^4$. The induced equation on any given conic is an element in the corresponding closed fiber of a certain vector bundle $A$ of rank 11 on the parameter space $X$. On any given plane $P$, and for any conic $C$ in $P$, we get the following exact sequence: $$ 0 \to{} H^0(O_P(3)) \to{} H^0(O_P(5)) \to{} H^0(O_C(5)) \to{} 0$$ As $C$ varies, these sequences glue to a short exact sequence of bundles on $X$: $$ 0 \to{} Symm^3 Q \otimes O(-z) \to{} Symm^5 Q \to{} A \to{} 0$$ We compute the class of $A$ in the Grothendieck group:

i5 : A = symmetricPower_5 Q - symmetricPower_3 Q ** OO(-z)

o5 = A

o5 : an abstract sheaf of rank 11 on X

A given conic is contained in the quintic if and only if the equation of the quintic vanishes identically on the conic. Hence the class of the locus of conics contained in the quintic is the top Chern class of $A$. Hence the number of them is the integral of this Chern class:

i6 : integral chern A

o6 = 609250

Conics on a quintic threefold -- an example

See also