plethysm -- Plethystic operations on representations

Synopsis

Usage:

pl = plethysm(f,g)

pl = f @ g
Inputs:
- f, a ring element, element of Symmetric ring or Schur ring
- g, a ring element, element of Symmetric ring or Schur ring
Outputs:
- pl, a ring element, element of the ring of g

Description

Given a symmetric functions f and the character g of a virtual representation of a product of general linear and symmetric groups, the method computes the character of the plethystic composition of f and g. The result of this operation will be an element of the ring of g. We use the binary operator @ as a synonym for the plethysm function.

i1 : R = symmetricRing(QQ,5);

i2 : pl = plethysm(h_2,h_3)

      6     4       2 2     3     3                2     2
o2 = e  - 5e e  + 7e e  - 2e  + 3e e  - 6e e e  + e  - 2e e  + 3e e  + e e
      1     1 2     1 2     2     1 3     1 2 3    3     1 4     2 4    1 5

o2 : R

i3 : toS pl

o3 = s  + s
      6    4,2

o3 : schurRing (QQ, s, 5)

i4 : S = schurRing(QQ,q,3);

i5 : h_2 @ q_{2,1}

o5 = q    + q      + q
      4,2    3,2,1    2,2,2

o5 : S

i6 : plethysm(q_{2,1},q_{2,1})

o6 = q      + q    + 2q      + q      + q      + 3q
      6,2,1    5,4     5,3,1    5,2,2    4,4,1     4,3,2

o6 : S

i7 : T = schurRing(S,t,2,GroupActing => "Sn");

i8 : plethysm(q_{1,1,1}-q_{2,1}+q_{3},q_{2,1}*t_2-t_{1,1})

o8 = (q    - q      - q    + q      + q      - q      + 2q     )t  - q  t
       6,3    6,2,1    5,4    5,2,2    4,4,1    4,3,2     3,3,3  2    () 1,1

o8 : T

i9 : p_3 @ (q_{2,1}*t_2-t_{1,1})

o9 = (q    - q      - q    + q      + q      - q      + 2q     )t  - q  t
       6,3    6,2,1    5,4    5,2,2    4,4,1    4,3,2     3,3,3  2    () 1,1

o9 : T

Ways to use plethysm :

plethysm(RingElement,RingElement)
plethysm(BasicList,RingElement) -- Plethystic operations on representations
plethysm(BasicList,ClassFunction) -- see plethysm(RingElement,ClassFunction) -- Plethystic operations on class functions
plethysm(RingElement,ClassFunction) -- Plethystic operations on class functions

For the programmer

The object plethysm is a method function.