splineDimensionTable -- a table with the dimensions of the graded pieces of a graded module

Synopsis

Usage:

T=splineDimensionTable(a,b,M)

T=splineDimensionTable(a,b,L,r)
Inputs:
- a, an integer, lowest degree in the table
- b, an integer, largest degree in the table
- M, a module, graded module
- L, a list, a list {V,F,E} of the vertices, facets and codimension one faces of a polyhedral complex
- r, an integer, degree of smoothnes
Outputs:
- T, a table expression, T= table with the dimensions of the graded pieces of M in the range a,b

Description

The output table gives you the dimensions of the graded pieces of the module M where the degree is between a and b.

i1 : V = {{0,0},{1,0},{1,1},{0,1}};

i2 : F = {{0,1,2},{0,2,3}};

i3 : E = {{0,1},{0,2},{0,3},{1,2},{2,3}};

i4 : M=splineModule(V,F,E,2);

i5 : splineDimensionTable(0,8,M)

     +---------+-+-+-+--+--+--+--+--+--+
o5 = |Degree   |0|1|2|3 |4 |5 |6 |7 |8 |
     +---------+-+-+-+--+--+--+--+--+--+
     |Dimension|1|3|6|11|18|27|38|51|66|
     +---------+-+-+-+--+--+--+--+--+--+

The table above records the dimensions dim$S^2_d(\Delta)$ (i.e. splines on $\Delta$ of smoothness 2 and degree at most d) for $d=$0,..,8.

You may instead input the list L={V,F,E} (or L={V,F}) of the vertices, facets and codimension one faces of the complex $\Delta$.

i6 : V = {{0,0},{1,0},{1,1},{0,1}};

i7 : F = {{0,1,2},{0,2,3}};

i8 : L = {V,F,E};

i9 : splineDimensionTable(0,8,L,2)

     +---------+-+-+-+--+--+--+--+--+--+
o9 = |Degree   |0|1|2|3 |4 |5 |6 |7 |8 |
     +---------+-+-+-+--+--+--+--+--+--+
     |Dimension|1|3|6|11|18|27|38|51|66|
     +---------+-+-+-+--+--+--+--+--+--+

The following complex, known as the Morgan-Scot partition, illustrates the subtle changes in dimension of spline spaces which may occur depending on geometry.

i10 : V = {{-1,-1},{1,-1},{0,1},{10,10},{-10,10},{0,-10}};

i11 : V'= {{-1,-1},{1,-1},{0,1},{10,10},{-10,10},{1,-10}};

i12 : F = {{0,1,2},{2,3,4},{0,4,5},{1,3,5},{1,2,3},{0,2,4},{0,1,5}};

i13 : M = splineModule(V,F,1);

i14 : M' = splineModule(V',F,1);

i15 : splineDimensionTable(0,4,M)

      +---------+-+-+-+--+--+
o15 = |Degree   |0|1|2|3 |4 |
      +---------+-+-+-+--+--+
      |Dimension|1|3|7|16|33|
      +---------+-+-+-+--+--+

i16 : splineDimensionTable(0,4,M')

      +---------+-+-+-+--+--+
o16 = |Degree   |0|1|2|3 |4 |
      +---------+-+-+-+--+--+
      |Dimension|1|3|6|16|33|
      +---------+-+-+-+--+--+

Notice that the dimension of the space of $C^1$ quadratic splines changes depending on the geometry of $\Delta$.

Ways to use splineDimensionTable :

splineDimensionTable(ZZ,ZZ,List,ZZ)
splineDimensionTable(ZZ,ZZ,Module)

For the programmer

The object splineDimensionTable is a method function.