Description
This method computes the ideal defining the point scheme of the (assumed to be Artin-Schelter regular) algebra B. This amounts to computing the ideal of maximal minors of the left quadratic matrix corresponding to the generators of the defining ideal of B.
The point scheme parametrizes the point modules over the algebra B. A $B$-point module is a module $M$ that is generated in degree zero and whose Hilbert function is one for every nonnegative integer. In the commutative case, the point scheme of a graded ring $R$ generated in degree one is simply $\operatorname{Proj}(R)$, so this object serves as a way to introduce geometry in a noncommutative context.
A straightforward calculation shows that a skew commutative polynomial ring in two variables still has point scheme given by $\mathbb{P}^1$, for example:
i1 : S = skewPolynomialRing(QQ,(-1)_QQ,{x_1,x_2})
Warning: F4 Algorithm not available over current coefficient ring or inhomogeneous ideal.
Converting to Naive algorithm.
o1 = S
o1 : FreeAlgebraQuotient
|
i2 : P = pointScheme(S,a)
o2 = ideal ()
o2 : Ideal of QQ[a ..a ]
1 2
|
In higher variables, one gets smaller point schemes, however. Indeed, the point scheme of the skew polynomial ring in four variables is a two-dimensional reducible scheme given by a union of six lines.
i3 : S = skewPolynomialRing(QQ,(-1)_QQ,{x_1..x_4})
Warning: F4 Algorithm not available over current coefficient ring or inhomogeneous ideal.
Converting to Naive algorithm.
o3 = S
o3 : FreeAlgebraQuotient
|
i4 : P = pointScheme(S,a)
2 2 2 2 2 2
o4 = ideal (-2a a a , -2a a a , 2a a a , 2a a a , -2a a a , 2a a a ,
1 2 3 1 2 3 1 2 4 1 2 4 1 2 3 1 3 4
------------------------------------------------------------------------
2 2 2 2 2 2
-2a a a , -2a a a , -2a a a , 2a a a , 2a a a , 2a a a )
1 3 4 2 3 4 2 3 4 1 2 4 1 3 4 2 3 4
o4 : Ideal of QQ[a ..a ]
1 4
|
i5 : netList minimalPrimes P
+--------------+
o5 = |ideal (a , a )|
| 4 3 |
+--------------+
|ideal (a , a )|
| 4 2 |
+--------------+
|ideal (a , a )|
| 4 1 |
+--------------+
|ideal (a , a )|
| 3 2 |
+--------------+
|ideal (a , a )|
| 3 1 |
+--------------+
|ideal (a , a )|
| 2 1 |
+--------------+
|
Three-dimensional Sklyanin algebras were shown by Artin-Tate-Van den Bergh to generically have point scheme given by a smooth elliptic curve, a defining equation of which we may obtain using this method.
i6 : S = threeDimSklyanin (frac(QQ[a,b,c]),{a,b,c},{x,y,z}, DegreeLimit => 3)
Warning: F4 Algorithm not available over current coefficient ring or inhomogeneous ideal.
Converting to Naive algorithm.
o6 = S
o6 : FreeAlgebraQuotient
|
i7 : P = pointScheme(S,X)
3 3 3 3 3 3
o7 = ideal(- a*b*c*X - a*b*c*X + (a + b + c )X X X - a*b*c*X )
1 2 1 2 3 3
o7 : Ideal of frac(QQ[a..c])[X ..X ]
1 3
|
The genericity condition $(3abc)^3 \neq (a^3 + b^3 + c^3)^3$ is somewhat visible here. Some non-generic Sklyanin algebras are still AS-regular:
i8 : S = threeDimSklyanin (QQ,{1,1,-2},{x,y,z})
Warning: F4 Algorithm not available over current coefficient ring or inhomogeneous ideal.
Converting to Naive algorithm.
o8 = S
o8 : FreeAlgebraQuotient
|
i9 : P = pointScheme(S,X)
3 3 3
o9 = ideal(2X + 2X - 6X X X + 2X )
1 2 1 2 3 3
o9 : Ideal of QQ[X ..X ]
1 3
|
i10 : netList minimalPrimes P
+----------------------------------------+
o10 = |ideal(X + X + X ) |
| 1 2 3 |
+----------------------------------------+
| 2 2 2 |
|ideal(X - X X + X - X X - X X + X )|
| 1 1 2 2 1 3 2 3 3 |
+----------------------------------------+
|
But as you can see, the point scheme is not a smooth elliptic curve. In fact, if we add a cube root of unity to the base ring, we can see that it is a union of three lines (although M2 has trouble detecting this outright):
i11 : R = QQ[zz,X_1,X_2,X_3]
o11 = R
o11 : PolynomialRing
|
i12 : PP = sub(P,R) + ideal {zz^2 + zz + 1}
3 3 3 2
o12 = ideal (2X + 2X - 6X X X + 2X , zz + zz + 1)
1 2 1 2 3 3
o12 : Ideal of R
|
i13 : minPP = minimalPrimes PP; netList minPP
+---------------------------------------------------------------------------------------------------------+
| 2 |
o14 = |ideal (X + X + X , zz + zz + 1) |
| 1 2 3 |
+---------------------------------------------------------------------------------------------------------+
| 2 2 2 2 |
|ideal (zz*X - zz*X - X + X , X - X X + X - X X - X X + X , zz*X - zz*X + X - X , zz + zz + 1)|
| 2 3 1 2 1 1 2 2 1 3 2 3 3 1 3 2 3 |
+---------------------------------------------------------------------------------------------------------+
| 2 2 2 2 |
|ideal (zz*X - zz*X + X - X , X - X X + X - X X - X X + X , zz*X - zz*X + X - X , zz + zz + 1)|
| 2 3 1 3 1 1 2 2 1 3 2 3 3 1 3 1 2 |
+---------------------------------------------------------------------------------------------------------+
|
i15 : minPP / degree
o15 = {2, 2, 2}
o15 : List
|
Indeed, this Sklyanin algebra is isomorphic to a skew polynomial algebra in three variables if the base field contains a cube root of unity.