character(ActionOnGradedModule,List) -- compute characters of graded components of a module

Synopsis

Function: character
Usage:

character(A,d)
Inputs:
- A, an instance of the type ActionOnGradedModule, a finite group action on a graded module
- d, a list, a (multi)degree
Outputs:
- an instance of the type Character, the character of the components of a module in given degrees

Description

Use this function to compute the characters of the finite group action on the graded components of a module. The second argument is the multidegree (as a list) or the degree (as an integer) of the desired component.

To illustrate, we compute the Betti characters of a symmetric group on the graded components of a quotient ring. The characters are determined by five permutations with cycle types, in order: 4, 31, 22, 211, 1111.

i1 : R = QQ[x_1..x_4]

o1 = R

o1 : PolynomialRing

i2 : I = ideal apply(subsets(gens R,2),product)

o2 = ideal (x x , x x , x x , x x , x x , x x )
             1 2   1 3   2 3   1 4   2 4   3 4

o2 : Ideal of R

i3 : G = {matrix{{x_2,x_3,x_4,x_1}},
          matrix{{x_2,x_3,x_1,x_4}},
          matrix{{x_2,x_1,x_4,x_3}},
          matrix{{x_2,x_1,x_3,x_4}},
          matrix{{x_1,x_2,x_3,x_4}} }

o3 = {| x_2 x_3 x_4 x_1 |, | x_2 x_3 x_1 x_4 |, | x_2 x_1 x_4 x_3 |, | x_2
     ------------------------------------------------------------------------
     x_1 x_3 x_4 |, | x_1 x_2 x_3 x_4 |}

o3 : List

i4 : Q = R/I

o4 = Q

o4 : QuotientRing

i5 : A = action(Q,G)

o5 = QuotientRing with 5 actors

o5 : ActionOnGradedModule

i6 : character(A,0)

o6 = Character over R
      
     (0, {0}) => | 1 1 1 1 1 |

o6 : Character

i7 : character(A,1)

o7 = Character over R
      
     (0, {1}) => | 0 1 0 2 4 |

o7 : Character

Synopsis

Usage:

character(A,lo,hi)
Inputs:
- A, an instance of the type ActionOnGradedModule, a finite group action on a graded module
- lo, an integer, the low degree
- hi, an integer, the high degree
Outputs:
- an instance of the type Character, the character of the components of a module in the given range of degrees

For $\mathbb{Z}$-graded modules, one may compute characters in a range of degrees by providing the lowest and highest degrees in the range as the second and third argument.

i8 : character(A,0,4)

o8 = Character over R
      
     (0, {0}) => | 1 1 1 1 1 |
     (0, {1}) => | 0 1 0 2 4 |
     (0, {2}) => | 0 1 0 2 4 |
     (0, {3}) => | 0 1 0 2 4 |
     (0, {4}) => | 0 1 0 2 4 |

o8 : Character

Ways to use this method: