Macaulay2 » Documentation
Packages » CompleteIntersectionResolutions :: isStablyTrivial
next | previous | forward | backward | up | index | toc

isStablyTrivial -- returns true if the map goes to 0 under stableHom

Synopsis

Description

A possible obstruction to the commutativity of the CI operators in codim c, even asymptotically, would be the non-triviality of the map M_{(k+4)} --> M_k \otimes \wedge^2(S^c) in the stable category of maximal Cohen-Macaulay modules.

In the following example, studied in the paper "Tor as a module over an exterior algebra" of Eisenbud, Peeva and Schreyer, the map is non-trivial...but it is stably trivial. The same goes for higher values of k (which take longer to compute). (note that in this case, with c = 3, two of the three alternating products are actually equal to 0, so we test only the third.)

Note that T is well-defined up to homotopy; so T^2 is well-defined mod mm^2.

i1 : kk = ZZ/101

o1 = kk

o1 : QuotientRing
 
i2 : S = kk[a,b,c]

o2 = S

o2 : PolynomialRing
 
i3 : ff = matrix"a2,b2,c2"

o3 = | a2 b2 c2 |

             1      3
o3 : Matrix S  <-- S
 
i4 : R = S/ideal ff

o4 = R

o4 : QuotientRing
 
i5 : M = R^1/ideal"a,bc"

o5 = cokernel | a bc |

                            1
o5 : R-module, quotient of R
 
i6 : k = 1

o6 = 1
 
i7 : m = k+5

o7 = 6
 
i8 : F = res(M, LengthLimit => m)

      1      2      4      7      11      16      22
o8 = R  <-- R  <-- R  <-- R  <-- R   <-- R   <-- R
                                                  
     0      1      2      3      4       5       6

o8 : ChainComplex
 
i9 : syzygies = apply(1..m, i->coker F.dd_i);
 
i10 : t1 = makeT(ff,F,k+4);
 
i11 : t2 = makeT(ff,F,k+2);
 
i12 : T2Components = flatten for i from 0 to 1 list(for j from i+1 to 2 list map(F_k, F_(k+4), t2_i*t1_j-t2_j*t1_i));
 
i13 : g = map(syzygies_k, syzygies_(k+4), T2Components_2)

o13 = {1} | 0 0 0 0 0 -c 0 0 b 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0  0 0 0 0 0 0 0 0 0 0 |

o13 : Matrix
 
i14 : isStablyTrivial g

o14 = true

See also

Ways to use isStablyTrivial :

For the programmer

The object isStablyTrivial is a method function.