ComplexMap _ ZZ -- access individual matrices in a complex map

Synopsis

Operator: _
Usage:

f_i
Inputs:
- f, a map of complexes,
- i, an integer, the homological index
Outputs:
- a matrix, the i-th map

Description

A complex map $f : C \to D$ of degree $d$ is a sequence of maps $f_i : C_i \to D_{i+d}$. This method allows one to access the individual $f_i$.

i1 : S = ZZ/101[a..c];

i2 : C = freeResolution coker matrix{{a^2, b^2, c^2}}

      1      3      3      1
o2 = S  <-- S  <-- S  <-- S
                           
     0      1      2      3

o2 : Complex

i3 : D = freeResolution coker vars S

      1      3      3      1
o3 = S  <-- S  <-- S  <-- S
                           
     0      1      2      3

o3 : Complex

i4 : f = randomComplexMap(D, C)

          1              1
o4 = 0 : S  <---------- S  : 0
               | 24 |

          3                                                      3
     1 : S  <-------------------------------------------------- S  : 1
               {1} | -36a-30b-29c -29a-24b-38c -39a-18b-13c |
               {1} | 19a+19b-10c  -16a+39b+21c -43a-15b-28c |
               {1} | -29a-8b-22c  34a+19b-47c  -47a+38b+2c  |

          3                                                                                                          3
     2 : S  <------------------------------------------------------------------------------------------------------ S  : 2
               {2} | 16a2+22ab-34b2+45ac-48bc-47c2 35a2+11ab+33b2-38ac+40bc+11c2 -37a2-13ab+30b2-10ac-18bc+39c2 |
               {2} | 47a2+19ab+7b2-16ac+15bc-23c2  46a2-28ab-3b2+ac+22bc-47c2    27a2-22ab-9b2+32ac-32bc-20c2   |
               {2} | 39a2+43ab-11b2-17ac+48bc+36c2 -23a2-7ab+29b2+2ac-47bc+15c2  24a2-30ab-15b2-48ac+39bc       |

          1                                                                       1
     3 : S  <------------------------------------------------------------------- S  : 3
               {3} | 33a3-49a2b-19ab2+44b3-33a2c+17abc-39b2c-20ac2+36bc2+9c3 |

o4 : ComplexMap

i5 : f_2

o5 = {2} | 16a2+22ab-34b2+45ac-48bc-47c2 35a2+11ab+33b2-38ac+40bc+11c2
     {2} | 47a2+19ab+7b2-16ac+15bc-23c2  46a2-28ab-3b2+ac+22bc-47c2   
     {2} | 39a2+43ab-11b2-17ac+48bc+36c2 -23a2-7ab+29b2+2ac-47bc+15c2 
     ------------------------------------------------------------------------
     -37a2-13ab+30b2-10ac-18bc+39c2 |
     27a2-22ab-9b2+32ac-32bc-20c2   |
     24a2-30ab-15b2-48ac+39bc       |

             3      3
o5 : Matrix S  <-- S

i6 : f_0

o6 = | 24 |

             1      1
o6 : Matrix S  <-- S

Indices that are outside of the concentration are automatically zero.

i7 : concentration f

o7 = (0, 3)

o7 : Sequence

i8 : f_-1

o8 = 0

o8 : Matrix 0 <-- 0

i9 : f_3

o9 = {3} | 33a3-49a2b-19ab2+44b3-33a2c+17abc-39b2c-20ac2+36bc2+9c3 |

             1      1
o9 : Matrix S  <-- S

i10 : f_4

o10 = 0

o10 : Matrix 0 <-- 0

Ways to use this method:

ComplexMap _ ZZ -- access individual matrices in a complex map

ComplexMap _ ZZ -- access individual matrices in a complex map

Synopsis

Description

See also

Ways to use this method: