isGolod -- Determines if a ring is Golod

Synopsis

Usage:

isGol = isGolod(R)
Inputs:
- R, a ring,
Outputs:
- isGol, a Boolean value,

Description

This function determines if the Koszul complex of a ring R admits a trivial Massey operation. If one exists, then R is Golod.

i1 : R = ZZ/101[a,b,c,d]/ideal{a^4+b^4+c^4+d^4}

o1 = R

o1 : QuotientRing

i2 : isGolod(R)

o2 = true

Hypersurfaces are Golod, but

i3 : R = ZZ/101[a,b,c,d]/ideal{a^4,b^4,c^4,d^4}

o3 = R

o3 : QuotientRing

i4 : isGolod(R)

o4 = false

complete intersections of higher codimension are not. Here is another example:

i5 : Q = ZZ/101[a,b,c,d]

o5 = Q

o5 : PolynomialRing

i6 : R = Q/(ideal vars Q)^2

o6 = R

o6 : QuotientRing

i7 : isGolod(R)

o7 = true

The above is a (CM) ring minimal of minimal multiplicity, hence Golod. The next example was found by Lukas Katthan, and appears in his arXiv paper 1511.04883. It is the first known example of an algebra that is not Golod, but whose Koszul complex has a trivial homology product.

i8 : Q = ZZ/101[x_1,x_2,y_1,y_2,z,w]

o8 = Q

o8 : PolynomialRing

i9 : I = ideal {x_1*x_2^2,z^2*w,y_1*y_2^2,x_2^2*z*w,y_2^2*z^2,x_1*x_2*y_1*y_2,x_2^2*y_2^2*z,x_1*y_1*z}

               2   2      2   2      2 2             2 2
o9 = ideal (x x , z w, y y , x z*w, y z , x x y y , x y z, x y z)
             1 2        1 2   2      2     1 2 1 2   2 2    1 1

o9 : Ideal of Q

i10 : R = Q/I

o10 = R

o10 : QuotientRing

i11 : isHomologyAlgebraTrivial koszulComplexDGA R

o11 = true

i12 : isGolod R

o12 = false

Note that since the Koszul complex is zero in homological degree beyond the embedding dimension, there are only finitely many Massey products that one needs to check to verify that a ring is Golod.

Ways to use isGolod :

isGolod(Ring)

For the programmer

The object isGolod is a method function.