oneStepGVDNyI -- computes the ideal $N_{y,I}$ for a given ideal and indeterminate

Let $y$ be a variable of the polynomial ring $R = k[x_1,\ldots,x_n]$. A monomial ordering $<$ on $R$ is said to be $y$-compatible if the initial term of $f$ satisfies ${\rm in}_<(f) = {\rm in}_<({\rm in}_y(f))$ for all $f \in R$. Here, ${\rm in}_y(f)$ is the initial $y$-form of $f$, that is, if $f = \sum_i \alpha_iy^i$ and $\alpha_d \neq 0$ but $\alpha_t = 0$ for all $t >d$, then ${\rm in}_y(f) = \alpha_d y^d$.

Given an ideal $I$ and a $y$-compatible monomial ordering $<$, let $G(I) = \{ g_1,\ldots,g_m\}$ be a Gröbner basis of $I$ with respect to this ordering. For $i=1,\ldots,m$, write $g_i$ as $g_i = y^{d_i}q_i + r_i$, where $y$ does not divide any term of $q_i$; that is, ${\rm in}_y(g_i) = y^{d_i}q_i$. Given this setup, the ideal $N_{y,I}$ is given by $$N_{y,I} = \langle q_i ~|~ d_i = 0\rangle$$ This functions takes an ideal $I$ and variable $y$, and returns $N_{y,I}$

The ideal $N_{y,I}$ does not depend upon the choice of the Gröbner basis or a particular $y$-compatible order (see comment after [KR, Definition 2.3]). When computing $N_{y,I}$ we use a lexicographical ordering on $R$ where $y > x_j$ for all $i \neq j$ if $y = x_i$ since this gives us a $y$-compatible order.

The ideal $I$ in the example below is the edge ideal of the complete graph $K_4$. For more on edge ideals, see the EdgeIdeals package.

i1 : R = QQ[a,b,c,d];

i2 : I = ideal(a*b, a*c, a*d, b*c, b*d, c*d); -- edge ideal of a complete graph K_4, a chordal graph

o2 : Ideal of R

i3 : oneStepGVDNyI(I, b)

o3 = ideal (c*d, a*d, a*c)

o3 : Ideal of R

i4 : L = oneStepGVD(I, b);

i5 : L_2 == oneStepGVDNyI(I, b) -- NyI is the second element in the list given by oneStepGVD

o5 = true

[KR] Patricia Klein and Jenna Rajchgot. Geometric vertex decomposition and liaison. Forum Math. Sigma, 9 (2021) e70:1-23.

This method is a shortcut to extract the ideal $N_{y,I}$ as computed in oneStepGVD. That is, to compute $N_{y,I}$, oneStepGVD is called in the background. As a result, work is also done in the background to compute $C_{y,I}$ at the same time, and as such, we encourage calling oneStepGVD directly if we want both the $C_{y,I}$ and $N_{y,I}$ ideals to avoid performing the same computation twice.