Macaulay2 » Documentation
Packages » GradedLieAlgebras :: extAlgebra
next | previous | forward | backward | up | index | toc

extAlgebra -- compute the Ext-algebra of a Lie algebra

Synopsis

Description

The Ext-algebra of the Lie algebra $L$ is $Ext_{UL}(F,F)$, where $F$ is the field of $L$ and $UL$ is the enveloping algebra of $L$. It is computed using the minimal model of $L$, see ExtAlgebra. If $R$ is a quadratic (skew)commutative Koszul algebra, and L is the value of koszulDual($R$) then extAlgebra(n,L) represents the ring $R$ up to degree $n$. A basis for $Ext_{UL}(F,F)$ as a vector space is represented by generators(ExtAlgebra). The symbol SPACE is used as multiplication of elements in the Ext-algebra and for multiplication by scalars.

i1 : F = lieAlgebra({a,b,c},Weights=>{{1,0},{1,0},{2,1}},
            Signs=>{1,1,1},LastWeightHomological=>true)

o1 = F

o1 : LieAlgebra
 
i2 : D = differentialLieAlgebra{0_F,0_F,a a + b b}

o2 = D

o2 : LieAlgebra
 
i3 : L=D/{a b,a c}

o3 = L

o3 : LieAlgebra
 
i4 : E=extAlgebra(3,L)

o4 = E

o4 : ExtAlgebra
 
i5 : describe E

o5 = generators => {ext_0, ext_1, ext_2, ext_3, ext_4}
     Weights => {{1, 1}, {1, 1}, {2, 2}, {2, 2}, {3, 3}}
     Signs => {0, 0, 0, 0, 0}
     lieAlgebra => L
     Field => QQ
     computedDegree => 3
 
i6 : (ext_0 - 2 ext_1) ext_2

o6 =  - 4ext_4

o6 : E
 
i7 : R=QQ[a,b,c]/{a*a,b*b,c*c}

o7 = R

o7 : QuotientRing
 
i8 : L=koszulDual(R)

o8 = L

o8 : LieAlgebra
 
i9 : E=extAlgebra(4,L)

o9 = E

o9 : ExtAlgebra
 
i10 : describe E

o10 = generators => {ext_0, ext_1, ext_2, ext_3, ext_4, ext_5, ext_6}
      Weights => {{1, 1}, {1, 1}, {1, 1}, {2, 2}, {2, 2}, {2, 2}, {3, 3}}
      Signs => {0, 0, 0, 0, 0, 0, 0}
      lieAlgebra => L
      Field => QQ
      computedDegree => 4
 
i11 : ext_0 ext_1 ext_2

o11 = ext_6

o11 : E

See also

Ways to use extAlgebra :

For the programmer

The object extAlgebra is a method function.