minimalPresentation(ZZ,LieAlgebra) -- compute a minimal presentation

Synopsis

Function: minimalPresentation
Usage:

M = minimalPresentation(n,L)
Inputs:
- n, an integer, the maximal degree
- L, an instance of the type LieAlgebra,
Optional inputs:
- Exclude => ..., default value {},
Outputs:
- M, an instance of the type LieAlgebra,

Description

The optional input given above is not relevant for Lie algebras. A minimal set of generators and relations for the Lie algebra $L$ (without differential) is given. In general the presentation applies to $H_0(L)$. The example $L$ below is the Lie algebra of strictly upper triangular $4\times 4$-matrices given by its multiplication table on the natural basis.

i1 : L=lieAlgebra({e12,e23,e34,e13,e24,e14},Weights=>{1,1,1,2,2,3})/
      {e12 e34,e12 e13,e12 e14,
       e23 e13,e23 e24,e23 e14,
       e34 e24,e34 e14,e13 e24,
       e13 e14,e24 e14,
       e12 e23 - e13,
       e12 e24 - e14,
       e13 e34 - e14,
       e23 e34 - e24}

o1 = L

o1 : LieAlgebra

i2 : M=minimalPresentation(3,L)

o2 = M

o2 : LieAlgebra

i3 : describe M

o3 = generators => {e12, e23, e34}
     Weights => {{1, 0}, {1, 0}, {1, 0}}
     Signs => {0, 0, 0}
     ideal => {(e34 e12), (e34 e34 e23), (e23 e34 e23), (e23 e23 e12), (e12 e23 e12)}
     ambient => LieAlgebra{...10...}
     diff => {}
     Field => QQ
     computedDegree => 0

i4 : dims(1,4,M)

o4 = {3, 2, 1, 0}

o4 : List

Ways to use this method: