invariants(...,DegreeBound=>...) -- degree bound for invariants of finite groups

Synopsis

• Usage:

  invariants G

• Inputs:
  • G, an instance of the type FiniteGroupAction
• Outputs:
  • L, a list, a minimal set of generating invariants for the group action

Description

This function is provided by the package InvariantRing.

This optional argument allows the user to provide an upper bound for the degree of the generating invariants of a finite group action. If no upper bound is provided, the order of the group is used as an upper bound. Providing a smaller upper bound may speed up the computation of invariants. However, if the value provided is too small the resulting list may not generate the ring of invariants.

The following example computes the invariants of the symmetric group on 4 elements.

i1 : R = QQ[x_1..x_4]

o1 = R

o1 : PolynomialRing

i2 : L = apply({"2134","2341"},permutationMatrix);

i3 : S4 = finiteAction(L,R)

o3 = R <- {| 0 1 0 0 |, | 0 0 0 1 |}
           | 1 0 0 0 |  | 1 0 0 0 |
           | 0 0 1 0 |  | 0 1 0 0 |
           | 0 0 0 1 |  | 0 0 1 0 |

o3 : FiniteGroupAction

i4 : elapsedTime invariants S4
 -- 0.928125 seconds elapsed

                          2    2    2    2   3    3    3    3   4    4    4  
o4 = {x  + x  + x  + x , x  + x  + x  + x , x  + x  + x  + x , x  + x  + x  +
       1    2    3    4   1    2    3    4   1    2    3    4   1    2    3  
     ------------------------------------------------------------------------
      4
     x }
      4

o4 : List

i5 : elapsedTime invariants(S4,DegreeBound=>4)
 -- 0.782901 seconds elapsed

Warning: stopping condition not met!
Output may not generate the entire ring of invariants.
Increase value of DegreeBound.


                          2    2    2    2   3    3    3    3   4    4    4  
o5 = {x  + x  + x  + x , x  + x  + x  + x , x  + x  + x  + x , x  + x  + x  +
       1    2    3    4   1    2    3    4   1    2    3    4   1    2    3  
     ------------------------------------------------------------------------
      4
     x }
      4

o5 : List

Further information

• Default value: infinity
• Function: invariants -- computes the generating invariants of a group action
• Option key: DegreeBound -- degree bound for invariants of finite groups

Caveat

See also

• finiteAction -- the group action generated by a list of matrices
• invariantRing -- the ring of invariants of a group action
• isInvariant -- check whether a polynomial is invariant under a group action

Functions with optional argument named DegreeBound :

• invariantRing(...,DegreeBound=>...)
• invariants(...,DegreeBound=>...) -- degree bound for invariants of finite groups