Ideal / Ideal -- quotient module

Synopsis

Operator: /
Usage:

I/J
Inputs:
- I, an ideal
- J, an ideal, in the same ring as I
Outputs:
- a module, The quotient module (I+J)/J

Description

i1 : R = QQ[a,b,c]

o1 = R

o1 : PolynomialRing

i2 : I = ideal vars R

o2 = ideal (a, b, c)

o2 : Ideal of R

i3 : M = I / I^2

o3 = subquotient (| a b c |, | a2 ab ac b2 bc c2 |)

                               1
o3 : R-module, subquotient of R

There is a difference between typing I/J and (I+J)/J in Macaulay2, although conceptually they are the same module. The former has as its generating set the generators of I, while the latter has as its (redundant) generators the generators of I and J. Generally, the former method is preferable.

i4 : gens M

o4 = | a b c |

             1      3
o4 : Matrix R  <-- R

i5 : N = (I + I^2)/I^2

o5 = subquotient (| a b c a2 ab ac b2 bc c2 |, | a2 ab ac b2 bc c2 |)

                               1
o5 : R-module, subquotient of R

i6 : gens N

o6 = | a b c a2 ab ac b2 bc c2 |

             1      9
o6 : Matrix R  <-- R

Ways to use this method: