matrix(Matrix) -- the matrix between generators

Synopsis

Function: matrix
Usage:

matrix f
Inputs:
- f, a matrix, a map of modules
Optional inputs:
- Degree => ..., default value null, create a matrix from a doubly-nested list of ring elements or matrices
Outputs:
- a matrix, If the source and target of f are free, then the result is f itself. Otherwise, the source and target will be replaced by the free modules whose basis elements correspond to the generators of the modules.

Description

Each homomorphism of modules $f : M \rightarrow N$ in Macaulay2 is induced from a matrix $f0 : \mathtt{cover} M \rightarrow \mathtt{cover} N$. This function returns this matrix.

i1 : R = QQ[a..d];

i2 : I = ideal(a^2,b^2,c*d)

             2   2
o2 = ideal (a , b , c*d)

o2 : Ideal of R

i3 : f = basis(3,I)

o3 = {2} | a b c d 0 0 0 0 0 0 0 0 |
     {2} | 0 0 0 0 a b c d 0 0 0 0 |
     {2} | 0 0 0 0 0 0 0 0 a b c d |

o3 : Matrix

i4 : source f

      12
o4 = R

o4 : R-module, free, degrees {12:3}

i5 : target f

o5 = image | a2 b2 cd |

                             1
o5 : R-module, submodule of R

The map f is induced by the following 3 by 12 matrix from R^12 to the 3 generators of I.

i6 : matrix f

o6 = {2} | a b c d 0 0 0 0 0 0 0 0 |
     {2} | 0 0 0 0 a b c d 0 0 0 0 |
     {2} | 0 0 0 0 0 0 0 0 a b c d |

             3      12
o6 : Matrix R  <-- R

To obtain the map that is the composite of this with the inclusion of I onto R, use super(Matrix).

i7 : super f

o7 = | a3 a2b a2c a2d ab2 b3 b2c b2d acd bcd c2d cd2 |

             1      12
o7 : Matrix R  <-- R

Ways to use this method: