upperBoundDegreeSingleGraded -- computes an upper bound for the degree of a rational map

Synopsis

Usage:

upperBoundDegreeSingleGraded(I)
Inputs:
- I, an ideal, an ideal defining the map
Outputs:
- an integer, an upper bound for the degree of the corresponding rational map

Description

Let $R$ be the polynomial ring $R=k[x_0,...,x_r]$ and $I$ be the homogeneous ideal $I=(f_0,f_1,...,f_s)$ where $deg(f_i)=d$. We compute the degree of the rational map $\mathbb{F}: \mathbb{P}^r \to \mathbb{P}^s$ defined by $$ (x_0: ... :x_r) \to (f_0(x_0,...,x_r), f_1(x_0,...,x_r), ..... , f_s(x_0,...,x_r)). $$ Using certain Hilbert functions the degree of the map is bounded (see Theorem 3.22 in Degree and birationality of multi-graded rational maps).

The following example is a rational map without base points:

i1 : R = QQ[x,y,z]

o1 = R

o1 : PolynomialRing

i2 : I = ideal(random(4, R), random(4, R), random(4, R));

o2 : Ideal of R

i3 : betti res I

            0 1 2 3
o3 = total: 1 3 3 1
         0: 1 . . .
         1: . . . .
         2: . . . .
         3: . 3 . .
         4: . . . .
         5: . . . .
         6: . . 3 .
         7: . . . .
         8: . . . .
         9: . . . 1

o3 : BettiTally

i4 : degreeOfMap I

o4 = 16

i5 : upperBoundDegreeSingleGraded I

o5 = 16

In the following examples we play with the relations of the Hilbert-Burch presentation and the degree of $\mathbb{F}$ (see Proposition 5.2 and Theorem 5.12):

i6 : A = matrix{ {x, x^2 + y^2},
                 {-y, y^2 + z*x},
                 {0, x^2}
               };

             3      2
o6 : Matrix R  <-- R

i7 : I = minors(2, A) -- a birational map

             2       2    3    2    3    2
o7 = ideal (x y + x*y  + y  + x z, x , -x y)

o7 : Ideal of R

i8 : degreeOfMap I

o8 = 1

i9 : upperBoundDegreeSingleGraded I

o9 = 2

i10 : A = matrix{ {x^2, x^2 + y^2},
                  {-y^2, y^2 + z*x},
                  {0, x^2}
                };

              3      2
o10 : Matrix R  <-- R

i11 : I = minors(2, A) -- a non birational map

               2 2    4    3    4    2 2
o11 = ideal (2x y  + y  + x z, x , -x y )

o11 : Ideal of R

i12 : degreeOfMap I

o12 = 2

i13 : upperBoundDegreeSingleGraded I

o13 = 4

i14 : A = matrix{ {x^3, x^2 + y^2},
                  {-y^3, y^2 + z*x},
                  {0, x^2}
                };

              3      2
o14 : Matrix R  <-- R

i15 : I = minors(2, A) -- a non birational map

              3 2    2 3    5    4    5    2 3
o15 = ideal (x y  + x y  + y  + x z, x , -x y )

o15 : Ideal of R

i16 : degreeOfMap I

o16 = 3

i17 : upperBoundDegreeSingleGraded I

o17 = 7

Caveat

To call the method "degreeOfMap(I)", the ideal $I$ should be in a single graded polynomial ring and dim(R/I) <= 1.

Ways to use upperBoundDegreeSingleGraded :

upperBoundDegreeSingleGraded(Ideal)

For the programmer

The object upperBoundDegreeSingleGraded is a method function.