shortcuts -- Some convenient shortcuts for multi-rational maps consisting of a single rational map

Synopsis

• Usage:

  rationalMap X <==> multirationalMap {rationalMap ideal X}

  rationalMap(X,a) <==> multirationalMap {rationalMap(ideal X,a)}

  rationalMap(X,a,b) <==> multirationalMap {rationalMap(ideal X,a,b)}

  multirationalMap f <==> multirationalMap {f}

• Inputs:
  • X, a multi-projective variety
  • a, an integer, or a list of integers
  • b, an integer
  • f, a rational map

i1 : X = PP_QQ^(1,3);

o1 : ProjectiveVariety, curve in PP^3

i2 : a = 4, b = 2;

i3 : phi = rationalMap X;

o3 : MultirationalMap (rational map from PP^3 to PP^2)

i4 : assert(phi <==> multirationalMap {rationalMap ideal X})

i5 : phi = rationalMap(X,a);

o5 : MultirationalMap (rational map from PP^3 to PP^21)

i6 : assert(phi <==> multirationalMap {rationalMap(ideal X,a)})

i7 : phi = rationalMap(X,a,b);

o7 : MultirationalMap (rational map from PP^3 to PP^5)

i8 : assert(phi <==> multirationalMap {rationalMap(ideal X,a,b)})

If you want to consider $X$ as a subvariety of another multi-projective variety $Y$, you may use the command X_Y. For instance, rationalMap(X_Y,a) returns the rational map from $Y$ defined by a basis of the linear system $|H^0(Y,\mathcal{I}_{X\subseteq Y}(a))|$ (basically, this is equivalent to trim((rationalMap(X,a))|Y)).

i9 : Y = random(3,X);

o9 : ProjectiveVariety, surface in PP^3

i10 : rationalMap(X_Y,a);

o10 : MultirationalMap (rational map from Y to PP^17)

i11 : rationalMap X_Y;

o11 : MultirationalMap (rational map from Y to PP^2)

See also

• rationalMap(Ideal) -- makes a rational map from an ideal
• rationalMap(Ideal,ZZ) -- makes a rational map from an ideal
• rationalMap(Ideal,ZZ,ZZ) -- makes a rational map from an ideal
• MultirationalMap <==> MultirationalMap -- equality of multi-rational maps with checks on internal data
• toRationalMap -- convert a multi-rational map consisting of a single rational map to a standard rational map