trim(MultirationalMap) -- trim the target of a multi-rational map

Synopsis

Function: trim
Usage:

trim Phi
Inputs:
- Phi, a multi-rational map, from a multi-projective variety $X$ to $\mathbb{P}^{k_1}\times\cdots\times\mathbb{P}^{k_n}$
Optional inputs:
- Strategy => ..., default value null,
Outputs:
- a multi-rational map, from $X$ to $\mathbb{P}^{s_1}\times\cdots\times\mathbb{P}^{s_n}$, with $s_i\leq k_i$, which is isomorphic to the original map, but whose image is not contained in any hypersurface of multidegree $(d_1,\ldots,d_n)$ with $\sum_{i=1}^n d_i = 1$

Description

i1 : K = ZZ/33331; C = PP_K^(1,4); -- rational normal quartic curve

o2 : ProjectiveVariety, curve in PP^4

i3 : Phi = rationalMap C; -- map defined by the quadrics through C

o3 : MultirationalMap (rational map from PP^4 to PP^5)

i4 : Q = random(2,C); -- random quadric hypersurface through C

o4 : ProjectiveVariety, hypersurface in PP^4

i5 : Phi = Phi|Q;

o5 : MultirationalMap (rational map from Q to PP^5)

i6 : image Phi

o6 = threefold in PP^5 cut out by 2 hypersurfaces of degrees 1^1 2^1 

o6 : ProjectiveVariety, threefold in PP^5

i7 : Psi = trim Phi;

o7 : MultirationalMap (rational map from Q to PP^4)

i8 : image Psi

o8 = hypersurface in PP^4 defined by a form of degree 2

o8 : ProjectiveVariety, hypersurface in PP^4

i9 : Phi || Phi || Psi;

o9 : MultirationalMap (rational map from Q x Q x Q to PP^5 x PP^5 x PP^4)

i10 : image oo

o10 = 9-dimensional subvariety of PP^5 x PP^5 x PP^4 cut out by 5 hypersurfaces of multi-degrees (0,0,2)^1 (0,1,0)^1 (0,2,0)^1 (1,0,0)^1 (2,0,0)^1 

o10 : ProjectiveVariety, 9-dimensional subvariety of PP^5 x PP^5 x PP^4

i11 : trim (Phi || Phi || Psi);

o11 : MultirationalMap (rational map from Q x Q x Q to PP^4 x PP^4 x PP^4)

i12 : image oo

o12 = 9-dimensional subvariety of PP^4 x PP^4 x PP^4 cut out by 3 hypersurfaces of multi-degrees (0,0,2)^1 (0,2,0)^1 (2,0,0)^1 

o12 : ProjectiveVariety, 9-dimensional subvariety of PP^4 x PP^4 x PP^4

Ways to use this method: