Macaulay2 » Documentation
Packages » NoetherianOperators :: noethOpsFromComponents
next | previous | forward | backward | up | index | toc

noethOpsFromComponents -- merge Noetherian operators for non-primary ideals

Synopsis

Description

Let $I$ be an unmixed ideal in a polynomial ring $R = K[x_1, ..., x_n]$, with primary decomposition $I = Q_1 \cap ... \cap Q_s$, where $Q_i$ is $P_i$-primary. If $N_i$ is a set of Noetherian operators for $Q_i$, then one can construct a set of differential operators $N$ for $I$ which satisfies the Noetherian operator condition: given $f \in R$, one has $f \in I$ iff $D(f) \in\sqrt{I}$ for all $D \in N$.

i1 : R = QQ[x,y,t]

o1 = R

o1 : PolynomialRing
 
i2 : I = intersect(ideal((y+t)^2), ideal(x^2, y^2 - t*x))

             4      2      3          2    2 2      3   2 2     2       2 2
o2 = ideal (y  - x*y t + 2y t - 2x*y*t  + y t  - x*t , x y  + 2x y*t + x t )

o2 : Ideal of R
 
i3 : radI = radical I

             2
o3 = ideal (y  + y*t, x*y + x*t)

o3 : Ideal of R
 
i4 : primes = associatedPrimes I

o4 = {ideal(y + t), ideal (y, x)}

o4 : List
 
i5 : L = primes / (P -> (P, noetherianOperators(I, P)))

o5 = {(ideal(y + t), {| 1 |, | dy |}), (ideal (y, x), {| 1 |, | dy |, |
     ------------------------------------------------------------------------
     tdy^2+2dx |, | tdy^3+6dxdy |})}

o5 : List
 
i6 : N = noethOpsFromComponents L

o6 = {| 1 |, | dy |, | (yt+t2)dy^2+(2y+2t)dx |, | (yt+t2)dy^3+(6y+6t)dxdy |}

o6 : List
 
i7 : all(flatten table(N, I_*, (D, f) -> (D f) % radI == 0), identity)

o7 = true

Note that this construction justifies the focus of Noetherian operators on the case that the ideal I is primary: in order to get a useful membership test for a non-primary (but still unmixed) ideal, it suffices to compute Noetherian operators on each primary component, and then combine them in the way given above.

See also

Ways to use noethOpsFromComponents :

For the programmer

The object noethOpsFromComponents is a method function.