specializedNoetherianOperators -- Noetherian operators evaluated at a point

Synopsis

Usage:

specializedNoetherianOperators(I, pt)
Inputs:
- I, an ideal, unmixed
- pt, a point, or a one-row matrix
Outputs:
- a list, of differential operators

Description

Numerically computes evaluations of Noetherian operators. If the point p lies on the variety of the minimal prime $P$, the function returns a set of specialized Noetherian operators of the $P$-primary component of $I$. The option DependentSet is required when dealing with ideals over numerical fields, or when dealing with non-primary ideals.

i1 : R = QQ[x,y,t];

i2 : Q1 = ideal(x^2, y^2 + x*t);

o2 : Ideal of R

i3 : Q2 = ideal((x+t)^2);

o3 : Ideal of R

i4 : I = intersect(Q1, Q2);

o4 : Ideal of R

i5 : P = radical Q1;

o5 : Ideal of R

i6 : pt = point{{0,0,2}};

i7 : A = specializedNoetherianOperators(I, pt, DependentSet => {x,y}) / normalize

o7 = {| 1 |, | dy |, | dy^2-dx |, | dy^3-3dxdy |}

o7 : List

i8 : B = noetherianOperators(I, P) /
         (D -> evaluate(D,pt)) /
         normalize

o8 = {| 1 |, | dy |, | dy^2-dx |, | dy^3-3dxdy |}

o8 : List

i9 : A == B

o9 = true

Over a non-exact field, the output will be non-exact

i10 : S = CC[x,y,t]

o10 = S

o10 : PolynomialRing

i11 : pt = point{{0,0,2.1}}

o11 = pt

o11 : Point

i12 : specializedNoetherianOperators(sub(I, S), pt, DependentSet => {x,y})

o12 = {| 1 |, | dy |, | .5dy^2-.47619dx |, | .166667dy^3-.47619dxdy |}

o12 : List

Caveat

It is assumed that the point lies on the variety of I

Ways to use specializedNoetherianOperators :

specializedNoetherianOperators(Ideal,AbstractPoint)
specializedNoetherianOperators(Ideal,Matrix)

For the programmer

The object specializedNoetherianOperators is a method function with options.