chi(CoherentSheaf) -- compute the Euler characteristic of a coherent sheaf

Synopsis

Function: chi
Usage:

chi F
Inputs:
- F, a coherent sheaf, on a complete simplicial normal toric variety
Outputs:
- a ring element, in the coefficient ring of intersection ring of the underlying variety

Description

By definition, the Euler characteristic of coherent sheaf $F$ on a variety $X$ is $\sum_i (-1)^i$ dim $HH^i (X, F)$. However, this methods uses the Hirzebruch-Riemann-Roch theorem to calculate the Euler characteristic.

For a nef line bundle on a normal toric variety, the Euler characteristic equals the number of lattice points in the corresponding polytope.

i1 : X0 = hirzebruchSurface 2;

i2 : degrees ring X0

o2 = {{1, 0}, {-2, 1}, {1, 0}, {0, 1}}

o2 : List

i3 : chi OO X0_2

o3 = 2

o3 : QQ[]

i4 : latticePoints X0_2

o4 = | 0 1 |
     | 0 0 |

              2       2
o4 : Matrix ZZ  <-- ZZ

i5 : assert all ({{1,0},{0,1},{1,1},{2,1},{1,2}}, p -> (
             D := p#0 * X0_2 + p#1 * X0_3;
             isNef D and chi OO D == rank source latticePoints D
             )
         )

i6 : chi OO (2 * X0_1)

o6 = -3

o6 : QQ[]

i7 : assert not isNef (2 * X0_1)

Ways to use this method: