centers -- even and odd action of the center of the even Clifford algebra

The center of the even Clifford algebra of an even-dimensional nonsingular quadratic form represented by its symmetric matrix of coefficients sM is a degree 2 extension of the ground ring with R[y]/(y^2- (-1)^d*f), where f is the branch equation, f = det sM. The action of y on the odd and even parts of a Clifford Module is represented by the pair of matrices c0, c1 which can be computed by the following formula of Haag (see Satz 1 of [U. Haag, Arch. Math. 57, 546-554 (1991)]).

Let M be the clifford module, with operators eOdd and eEv as usual, and let sM be the 2d x 2d symmetric matrix of the quadratic form, produced by M.symmetricM. Let skM be the alternating matrix formed by taking the "top half" of sM and subtracting the "bottom half". For any even length ordered sublist I = i_1,i_2...i_{2k} of [2d], let eo_I = eEv_{i_1}*eOdd_{i_1} \cdots eEv_{i_{2k}}*eOdd_{i_{2k}} and, similarly, oe_I = eOdd_{i_1}*eEv_{i_1} \cdots eOdd_{i_{2k}}*eEv_{i_{2k}}. Let J be the complement of I. Then

c1 = sum (-1)^{sgn J} Pfaffian((skM_J)^J)*eo_I

c0 = sum (-1)^{sgn J} Pfaffian((skM_J)^J)*oe_I

where the index I runs over all even length ordered subsets of [2d].

i1 : kk=ZZ/101; d=1;

i3 : n=2*d

o3 = 2

i4 : R=kk[a_0..a_(binomial(n+2,2)-1)]

o4 = R

o4 : PolynomialRing

i5 : S=kk[x_0..x_(n-1),a_0..a_(binomial(n+2,2)-1)]

o5 = S

o5 : PolynomialRing

i6 : M=genericSymmetricMatrix(S,a_0,n)

o6 = | a_0 a_1 |
     | a_1 a_2 |

             2      2
o6 : Matrix S  <-- S

i7 : X=(vars S)_{0..n-1}

o7 = | x_0 x_1 |

             1      2
o7 : Matrix S  <-- S

i8 : Y=X*M

o8 = | x_0a_0+x_1a_1 x_0a_1+x_1a_2 |

             1      2
o8 : Matrix S  <-- S

i9 : (M1,M2)=matrixFactorizationK(X,Y);

i10 : (eOdd,eEv)=cliffordOperators(M1,M2,R);

i11 : sM = symMatrix(eOdd,eEv)

o11 = | a_0 a_1 |
      | a_1 a_2 |

              2      2
o11 : Matrix R  <-- R

i12 : f = det sM

         2
o12 = - a  + a a
         1    0 2

o12 : R

i13 : f == (cliffordModule(eOdd,eEv)).hyperellipticBranchEquation

o13 = true

i14 : (c0,c1)=centers(eOdd,eEv)

o14 = ({-3} | 0  -a_1^2+a_0a_2 |, {-1} | -a_1 -a_2 |)
       {-2} | -1 0             |  {-1} | a_0  a_1  |

o14 : Sequence

i15 : assert(c0^2-(-1)^d*f*id_(source c0)==0)

i16 : assert(c1^2-(-1)^d*f*id_(source c1)==0)