polyhedronFromHData -- Constructing a polyhedron from its H-representation, i.e. inequalities and equations

Synopsis

Usage:

P = polyhedronFromHData(I, v)

P = polyhedronFromHData(I, v, E, w)
Inputs:
- I, a matrix, The inequalities
- v, a matrix, The right hand side of the inequalities
- E, a matrix, The equations
- w, a matrix, The right hand side of the equations
Outputs:
- P, a convex polyhedron,

Description

Constructs a polyhedron from inequalities and equations. Uses the negative halfspace defined by the equations, the normal vectors of every inequality point outside the polyhedron.

The polyhedron is defined by $\{x\in\mathbb{R}\ |\ I * x\le v,\ E * x=w\}$.

Please see V- and H-representation on the conventions we use for cones and polyhedra.

i1 : S = simplex 2

o1 = S

o1 : Polyhedron

i2 : facets S

o2 = (| -1 0  |, | 0 |)
      | 0  -1 |  | 0 |
      | 1  1  |  | 1 |

o2 : Sequence

i3 : SCopy = polyhedronFromHData facets S

o3 = SCopy

o3 : Polyhedron

i4 : assert(vertices S == vertices SCopy)

i5 : S = stdSimplex 2

o5 = S

o5 : Polyhedron

i6 : facets S

o6 = (| -1 0  0  |, 0)
      | 0  -1 0  |
      | 0  0  -1 |

o6 : Sequence

i7 : hyperplanes S

o7 = (| 1 1 1 |, | 1 |)

o7 : Sequence

i8 : SCopy = polyhedronFromHData(join(facets S, hyperplanes S))

o8 = SCopy

o8 : Polyhedron

i9 : assert(vertices S == vertices SCopy)

Ways to use polyhedronFromHData :

polyhedronFromHData(Matrix,Matrix)
polyhedronFromHData(Matrix,Matrix,Matrix,Matrix)

For the programmer

The object polyhedronFromHData is a method function.