Example: Hibi ideals

The Hibi ideal of $P$ is a MonomialIdeal built over a ring in $2n$ variables $x_0, \ldots, x_{n-1}, y_0, \ldots, y_{n-1}$, where $n$ is the size of the ground set of $P$. The generators of the ideal are in bijection with order ideals in $P$. Let $I$ be an order ideal of $P$. Then the associated monomial is the product of the $x_i$ associated with members of $I$ and the $y_i$ associated with non-members of $I$.

i1 : P = divisorPoset 12;

i2 : HP = hibiIdeal P

o2 = monomialIdeal (x x x x x x , x x x x x y , x x x x y y , x x x x y y ,
                     0 1 2 3 4 5   0 1 2 3 4 5   0 1 2 4 3 5   0 1 2 3 4 5 
     ------------------------------------------------------------------------
     x x x y y y , x x x y y y , x x y y y y , x x y y y y , x y y y y y ,
      0 1 3 2 4 5   0 1 2 3 4 5   0 2 1 3 4 5   0 1 2 3 4 5   0 1 2 3 4 5 
     ------------------------------------------------------------------------
     y y y y y y )
      0 1 2 3 4 5

o2 : MonomialIdeal of QQ[x ..x , y ..y ]
                          0   5   0   5

Herzog and Hibi proved that every power of a Hibi ideal has a linear resolution.

i3 : betti res HP

            0  1  2 3
o3 = total: 1 10 12 3
         0: 1  .  . .
         1: .  .  . .
         2: .  .  . .
         3: .  .  . .
         4: .  .  . .
         5: . 10 12 3

o3 : BettiTally

i4 : betti res (HP^2)

            0  1   2  3  4 5
o4 = total: 1 50 100 66 16 1
         0: 1  .   .  .  . .
         1: .  .   .  .  . .
         2: .  .   .  .  . .
         3: .  .   .  .  . .
         4: .  .   .  .  . .
         5: .  .   .  .  . .
         6: .  .   .  .  . .
         7: .  .   .  .  . .
         8: .  .   .  .  . .
         9: .  .   .  .  . .
        10: .  .   .  .  . .
        11: . 50 100 66 16 1

o4 : BettiTally

i5 : betti res (HP^3)

            0   1   2   3   4  5 6
o5 = total: 1 175 450 425 180 33 2
         0: 1   .   .   .   .  . .
         1: .   .   .   .   .  . .
         2: .   .   .   .   .  . .
         3: .   .   .   .   .  . .
         4: .   .   .   .   .  . .
         5: .   .   .   .   .  . .
         6: .   .   .   .   .  . .
         7: .   .   .   .   .  . .
         8: .   .   .   .   .  . .
         9: .   .   .   .   .  . .
        10: .   .   .   .   .  . .
        11: .   .   .   .   .  . .
        12: .   .   .   .   .  . .
        13: .   .   .   .   .  . .
        14: .   .   .   .   .  . .
        15: .   .   .   .   .  . .
        16: .   .   .   .   .  . .
        17: . 175 450 425 180 33 2

o5 : BettiTally

Moreover, they proved that the projective dimension of the Hibi ideal is the Dilworth number of the poset, i.e., the maximum length of an antichain of $P$.

i6 : pdim module HP

o6 = 2

i7 : dilworthNumber P

o7 = 2

They further proved that the $i^{\rm th}$ Betti number of the quotient of a Hibi ideal is the number of intervals of the distributiveLattice of $P$ isomorphic to the rank $i$ boolean lattice. Using an exercise in Stanley's ``Enumerative Combinatorics'', we recover this instead by looking at the number of elements of the distributive lattice that cover exactly $i$ elements.

i8 : LP = distributiveLattice P;

i9 : cvrs = partition(last, coveringRelations LP);

i10 : iCvrs = tally apply(keys cvrs, i -> #cvrs#i);

i11 : gk = prepend(1, apply(sort keys iCvrs, k -> iCvrs#k))

o11 = {1, 6, 3}

o11 : List

i12 : apply(#gk, i -> sum(i..<#gk, j -> binomial(j, i) * gk_j))

o12 = {10, 12, 3}

o12 : List

Example: Hibi ideals

See also