isModuleFinite(RingMap) -- whether the target of a ring map is finitely generated over source

Synopsis

Function: isModuleFinite
Usage:

isModuleFinite f

isModuleFinite R
Inputs:
- f, a ring map, or $R$ a ring
Outputs:
- a Boolean value,

Description

A ring map $f \colon A \to B$ makes $B$ into a module over $A$. This method returns true if and only if this module is a finitely generated $A$-module.

i1 : kk = QQ;

i2 : A = kk[t];

i3 : C = kk[x,y];

i4 : B = C/(y^2-x^3);

i5 : f = map(A, B, {t^2, t^3})

                  2   3
o5 = map (A, B, {t , t })

o5 : RingMap A <-- B

i6 : isWellDefined f

o6 = true

i7 : isModuleFinite f

o7 = true

i8 : f = map(kk[x,y], A, {x+y})

o8 = map (QQ[x..y], A, {x + y})

o8 : RingMap QQ[x..y] <-- A

i9 : assert not isModuleFinite f

If a ring $R$ is given, this method returns true if and only if $R$ is a finitely generated module over its coefficient ring.

i10 : A = kk[x]

o10 = A

o10 : PolynomialRing

i11 : B = A[y]/(y^3+x*y+3)

o11 = B

o11 : QuotientRing

i12 : isModuleFinite B

o12 = true

Ways to use this method: