Example Type [300b] -- An example of doubling construction

To get a quartic form $F$ of type [300b], we start with a set of $7$ points and let $F$ be power sum of them.

i1 : kk = ZZ/101;

i2 : R = kk[x_0..x_3];

i3 : HT = bettiStrataExamples(R);

i4 : MGamma = (HT#"[300b]")_0

o4 = | 1 0 0 0 1 19  -8  |
     | 0 1 0 0 1 19  -22 |
     | 0 0 1 0 1 -10 -29 |
     | 0 0 0 1 1 -29 -24 |

             4      7
o4 : Matrix R  <-- R

i5 : F = quartic MGamma;

We check the type of $F$.

i6 : quarticType F

o6 = [300ab]

The function quarticType cannot distinguish between type [300a] and [300b]. However, given MGamma, we now check that $F$ is of type [300b]. Let $I_{\Gamma}$ be the ideal defining the $7$ points.

i7 : Fperp = inverseSystem F;

o7 : Ideal of R

i8 : betti res Fperp

            0 1  2 3 4
o8 = total: 1 7 12 7 1
         0: 1 .  . . .
         1: . 3  . . .
         2: . 4 12 4 .
         3: . .  . 3 .
         4: . .  . . 1

o8 : BettiTally

i9 : IGamma = pointsIdeal MGamma;

o9 : Ideal of R

i10 : degree IGamma

o10 = 7

i11 : decompose IGamma -- 7 points, therefore the rank is at most 7

o11 = {ideal (x , x , x ), ideal (x , x , x ), ideal (x , x , x ), ideal (x ,
               3   2   1           3   2   0           3   1   0           2 
      -----------------------------------------------------------------------
      x , x ), ideal (x  - x , x  - x , x  - x ), ideal (x  + 31x , x  +
       1   0           2    3   1    3   0    3           2      3   1  
      -----------------------------------------------------------------------
      32x , x  + 32x ), ideal (x  + 3x , x  - 43x , x  - 34x )}
         3   0      3           2     3   1      3   0      3

o11 : List

i12 : betti res IGamma

             0 1 2 3
o12 = total: 1 4 6 3
          0: 1 . . .
          1: . 3 . .
          2: . 1 6 3

o12 : BettiTally

Let $Q$ be the quadratic part of $I_{\Gamma}$. We check that $Q$ is a complete intersection. Performing Construction 2.17, we obtain a doubling of $I_{\Gamma}$, which equals $F^{\perp}$.

i13 : Q = ideal super basis(2,IGamma);

o13 : Ideal of R

i14 : betti res Q

             0 1 2 3
o14 = total: 1 3 3 1
          0: 1 . . .
          1: . 3 . .
          2: . . 3 .
          3: . . . 1

o14 : BettiTally

i15 : Ip = Q:IGamma;

o15 : Ideal of R

i16 : betti res Ip

             0 1 2 3
o16 = total: 1 3 3 1
          0: 1 3 3 1

o16 : BettiTally

i17 : v = random(2,(Fperp:Ip));

i18 : Fperp == IGamma + v*Ip

o18 = true

Example Type [300b] -- An example of doubling construction

See also