We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{6} \cup X_{11} \subset \bf{P}^7$, of degree 17, having Betti table of type [310]. For an artinian reduction $A_F$, the quadratic part of the ideal $F^\perp$ is the ideal of a conic and two independent points $p_1,p_2$, and $F^\perp$ contains a pencil of ideals of five points on the conic and the two fixed points $p_1,p_2$. We construct $X_{11}$ in a quadric in a P6, and $X_{6}$ in a quadric in a P5. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.
The Betti table is
$\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&8&14&8&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&3&1&\text{.}&\text{.}\\ \text{2:}&\text{.}&5&12&5&\text{.}\\ \text{3:}&\text{.}&\text{.}&1&3&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $
i1 : kk = QQ;
|
i2 : U = kk[y0,y1,y2,y3,y4,y5,y6,y7];
|
i3 : P4a = ideal(y0,y1,y2); --a P4
o3 : Ideal of U
|
i4 : P4b = ideal(y4,y5,y6); --another P4
o4 : Ideal of U
|
i5 : P5 = ideal(y4,y5);-- a P5 containing P4b
o5 : Ideal of U
|
i6 : P6 = ideal(y6);--a P6 containing P4b
o6 : Ideal of U
|
i7 : CI222 = ideal(random(2,P4a),random(2,P4a),random(2,P4a));--a complete intersection (2,2,2) containing P4a
o7 : Ideal of U
|
i8 : Y7 = CI222:P4a; -- a 4-fold of degree 7 linked (2,2,2) to a P4a
o8 : Ideal of U
|
i9 : CI23 = ideal(random(2,Y7),random(3,Y7));--a complete intersection (2,3) that contains Y7
o9 : Ideal of U
|
i10 : Z6 = P4b + CI23; --a complete intersection (2,3) in P4b that contain the intersection of P4b and Y7
o10 : Ideal of U
|
i11 : X6 = P5 + ideal(random(2,Z6),random(3,Z6));-- a complete intersection (2,3) in P5 with hyperplane section Z6
o11 : Ideal of U
|
i12 : Y67 = intersect(Y7,Z6);--the union of the 4-fold Y7 and the Z6
o12 : Ideal of U
|
i13 : Y18 = CI23 + random(3,Y67);--a complete intersection (2,3,3) that contains Y7 and Z6
o13 : Ideal of U
|
i14 : Y11 = Y18:Y7;-- a 4-fold of degree 11 that contains Z6
o14 : Ideal of U
|
i15 : X11 = P6 + Y11; --a 3-fold of degree 11 that contains Z6
o15 : Ideal of U
|
i16 : X17 = intersect(X11,X6); -- a AG 3-fold in P7 of type (310)
o16 : Ideal of U
|