Type [441a], CY of degree 16 -- lifting to a 3-fold with components of degrees 12, 4

We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{12} \cup X_{4} \subset \bf{P}^7$, of degree 16, having Betti table of type [441], and is on component [441a]. For an artinian reduction $A_F$, the quadratic part of the ideal $F^\perp$ is the ideal of a conic and an independant point p, and $F^\perp$ contains pencils of ideals of five points on the conic and the point p. So we construct $X_{12}$ in a pencil of codimension 3 varieties of degree 5 in a quadric in a P6, and $X_{4}$ in an independant P4. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.

The Betti table is $\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&9&16&9&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&4&1&\text{.}\\ \text{2:}&\text{.}&4&8&4&\text{.}\\ \text{3:}&\text{.}&1&4&4&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $

i1 : kk=QQ;

i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7];

i3 : P3=ideal(y0,y1,y2,y3);--a P3

o3 : Ideal of U

i4 : P4=ideal(y1,y2,y3);--a P4

o4 : Ideal of U

i5 : P6=ideal(y0);--a P6

o5 : Ideal of U

i6 : M24=matrix{{y1,y2,random(2,U),random(2,U)},{y2,y3,random(2,U),random(2,U)}};--a 2x4 matrix with two columns of linear and two of quadratic forms

             2      4
o6 : Matrix U  <-- U

i7 : X12=P6+minors(2,M24);--a 3-fold of degree 12 in P6

o7 : Ideal of U

i8 : Z4=P3+X12;--a quartic surface in X12

o8 : Ideal of U

i9 : X4=P4+ideal(random(4,Z4));--a quartic 3-fold

o9 : Ideal of U

i10 : X16=intersect(X12,X4);-- a 3-fold of degree 16 in P7 with betti table of type 441

o10 : Ideal of U

i11 : betti res X16

             0 1  2 3 4
o11 = total: 1 9 16 9 1
          0: 1 .  . . .
          1: . 4  4 1 .
          2: . 4  8 4 .
          3: . 1  4 4 .
          4: . .  . . 1

o11 : BettiTally