Type [562] with a lifting of type II, a CY of degree 15 via linkage -- lifting to a 3-fold with components of degrees 7, 4, 4

We construct via linkage an arithmetically Gorenstein 3-fold $X = X_7& \cup X_{4} \cup X_{4}' \subset \bf{P}^7$, of degree 15, with components of degrees $7, 4, 4$, having Betti table of type [562]. For an artinian reduction $A_F$, the ideal $F^\perp$ contains a pencil of ideals $I_\Gamma$, where $\Gamma=\Gamma_3\cup p_1\cup p_2$, the union of a three points in a fixed line and two independant points outside the line. So we construct $X_7$ in the intersection of two cubics in a P5 and $X_4$ and $X_4'$ as quartics in an independant P4s. In the construction the intersection $X\cup (X'\cap X'')$ of a component $X$ with the two others is an anticanonical divisor on $X$.

The betti table is $\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&9&16&9&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&5&6&2&\text{.}\\ \text{2:}&\text{.}&2&4&2&\text{.}\\ \text{3:}&\text{.}&2&6&5&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $

$X_7$ is linked to a reducible quadric 3-fold $Y$ in a complete intersection $(1,1,3,3)$. $X_4$ and $X_4'$ are quartic 3-folds that each intersect $X_7$ in a cubic surface, while they intersect each other in a plane. The cubic surfaces are the intersection of $X_7$ with the components of $Y$, and the plane is the intersection of these components.

i1 : kk=QQ;

i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7];

i3 : P5=ideal(y0,y1);--a P5

o3 : Ideal of U

i4 : P3a=ideal(y0,y1,y2,y3);-- a P3

o4 : Ideal of U

i5 : P3b=ideal(y0,y1,y2,y4);-- another P3

o5 : Ideal of U

i6 : P4a=ideal(y0,y2,y3);-- a P4

o6 : Ideal of U

i7 : P4b=ideal(y1,y2,y4);-- a P4

o7 : Ideal of U

i8 : X2=ideal(y0,y1,y2,y3*y4);--a reducible quadric

o8 : Ideal of U

i9 : CI1133=P5+ideal(random(3,X2),random(3,X2));--a complete intersection (1,1,3,3) that contain X2.

o9 : Ideal of U

i10 : X7=CI1133:X2;  -- a 3-fold of degree 7, linked (1,1,3,3) to X2

o10 : Ideal of U

i11 : (dim X7, degree X7)

o11 = (4, 7)

o11 : Sequence

i12 : Z3a=P3a+X7; -- a cubic surface

o12 : Ideal of U

i13 : Z4a=intersect(Z3a,P3b);-- the union of Z3a and P3b

o13 : Ideal of U

i14 : X4a=P4a+ideal(random(4,Z4a));-- a quartic 3-fold in P4 that contains a plane in P3b and the cubic surface Z3

o14 : Ideal of U

i15 : (dim X4a, degree X4a)

o15 = (4, 4)

o15 : Sequence

i16 : Z3b=X7+P3b;-- a cubic surface

o16 : Ideal of U

i17 : Z4b=intersect(Z3b,P3a);-- the union of Z3b and P3b

o17 : Ideal of U

i18 : X4b=P4b+ideal(random(4,Z4b));-- a quartic 3-fold in P4 that contains a plane in P3b and the cubic surface Z3

o18 : Ideal of U

i19 : (dim X4b, degree X4b)

o19 = (4, 4)

o19 : Sequence

The union $X = X_7 \cup X_4 \cup X_4' \subset \PP^7$ has Betti table [562].

i20 : X15=intersect(X7,X4a,X4b);--a 3-fold of degree 15, with betti table of type [562], with three components, X7 of degree 7, and X4a and X4b of degree 4.

o20 : Ideal of U

i21 : (dim X15, degree X15)

o21 = (4, 15)

o21 : Sequence

i22 : betti res X15

             0 1  2 3 4
o22 = total: 1 9 16 9 1
          0: 1 .  . . .
          1: . 5  6 2 .
          2: . 2  4 2 .
          3: . 2  6 5 .
          4: . .  . . 1

o22 : BettiTally

Type [562] with a lifting of type II, a CY of degree 15 via linkage -- lifting to a 3-fold with components of degrees 7, 4, 4

See also