minimalPolynomial -- the minimal polynomial of an element of an Artinian ring

Synopsis

• Usage:

  minimalPolynomial(f)

  minimalPolynomial(g,I)

• Inputs:
  • f, a ring element, an element of an Artinian ring
  • g, a ring element, a polynomial
  • I, an ideal, a zero-dimensional ideal
• Optional inputs:
  • Strategy => ..., default value 0, set method for computing the minimal polynomial
• Outputs:
  • a ring element, the desired minimal polynomial. See description

Description

This computes the minimal polynomial of a ring element f in the Artinian ring ring f, or the minimal polynomial of a polynomial g in the Artinian ring (ring g)/I. When f is a variable in ring f, this is the eliminant with respect to that variable.

i1 : R = QQ[x,y]

o1 = R

o1 : PolynomialRing

i2 : I = ideal(y^2 - x^2 - 1,x - y^2 + 4*y - 2)

               2    2         2
o2 = ideal (- x  + y  - 1, - y  + x + 4y - 2)

o2 : Ideal of R

i3 : minimalPolynomial(y,I)

      4     3      2
o3 = Z  - 8Z  + 19Z  - 16Z + 5

o3 : QQ[Z]

i4 : S = R/I

o4 = S

o4 : QuotientRing

i5 : minimalPolynomial(y)

      4     3      2
o5 = Z  - 8Z  + 19Z  - 16Z + 5

o5 : QQ[Z]

We provide two examples to compute minimal polynomials given by Strategy => 0 (computes the kernel of $k[T]\to$ ring f by sending $T$ to f) and Strategy => 1 (a minimal linear combination of powers of the input).

i6 : minimalPolynomial(x,Strategy => 0)

      4     3     2
o6 = Z  - 2Z  - 9Z  - 6Z - 7

o6 : QQ[Z]

i7 : minimalPolynomial(x,Strategy => 1)

      4     3     2
o7 = Z  - 2Z  - 9Z  - 6Z - 7

o7 : QQ[Z]