resLengthThreeTorAlg -- the Tor algebra presented as a graded-commutative ring

Synopsis

Usage:

resLengthThreeTorAlg F, resLengthThreeTorAlg(F,L)
Inputs:
- F, a chain complex, a length three free resolution of a cyclic module
- L, a list, of three symbols
Outputs:
- a quotient ring, the Tor algebra presented as a quotient of a graded-commutative free algebra over the residue field of the ambient ring

Description

For a free resolution F over a ring Q, the function returns the algebra $Tor^Q(R,k)$ as a quotient of a graded-commutative free algebra over the residue field of Q. The basis vectors in degrees 1, 2, and 3 are named with the symbols from the list L. The default symbols are e, f, and g.

i1 : Q = QQ[x,y,z];

i2 : A = resLengthThreeTorAlg res ideal (x^2,y^2,z^2)

o2 = A

o2 : QuotientRing

i3 : describe A

                    QQ[e ..f , g ]
                        1   3   1
o3 = --------------------------------------------
     (e e  - f , e e  - f , e e  - f , e f  - g )
       2 3    3   1 3    2   1 2    1   1 3    1

i4 : e_1*e_2

o4 = f
      1

o4 : A

i5 : e_1*f_2

o5 = 0

o5 : A

i6 : e_1*f_3

o6 = g
      1

o6 : A

i7 : f_1*f_2

o7 = 0

o7 : A

The ambient ring Q does not need to be a polynomial algebra.

i8 : P = QQ[u,v,x,y,z];

i9 : Q = P/ideal(u^2,u*v);

i10 : A = resLengthThreeTorAlg ( res ideal (x^2,x*y,y^2,z^2), {a,b,c} )

o10 = A

o10 : QuotientRing

i11 : describe A

                                                       QQ[a ..a , b ..b , c ..c ]
                                                           1   4   1   5   1   2
o11 = ---------------------------------------------------------------------------------------------------------------------------
                                                                                                                     2         2
      (a a  - b , a a  - b , a a  - b , a a , a a , a a , a b  + c , a b , a b , a b , a b  + c , a b , a b , a b , b , b b , b )
        3 4    3   2 4    4   1 4    5   2 3   1 3   1 2   4 2    2   3 2   2 2   1 2   4 1    1   3 1   2 1   1 1   2   1 2   1

i12 : P = QQ[u,v];

i13 : Q = (P/ideal(u^2,u*v))[x,y,z];

i14 : A = resLengthThreeTorAlg ( res ideal (x^2,x*y,y^2,z^2), {a,b,c} )

o14 = A

o14 : QuotientRing

i15 : describe A

                                                       QQ[a ..a , b ..b , c ..c ]
                                                           1   4   1   5   1   2
o15 = ---------------------------------------------------------------------------------------------------------------------------
                                                                                                                     2         2
      (a a  - b , a a  - b , a a  - b , a a , a a , a a , a b  - c , a b , a b , a b , a b  - c , a b , a b , a b , b , b b , b )
        3 4    5   2 4    4   1 4    3   2 3   1 3   1 2   4 2    2   3 2   2 2   1 2   4 1    1   3 1   2 1   1 1   2   1 2   1

Caveat

For the function to return an algebra over the residue field of the ambient ring Q that ring must a homogeneous quotient of a polynomial algebra over a field.

Ways to use resLengthThreeTorAlg :

resLengthThreeTorAlg(ChainComplex)
resLengthThreeTorAlg(ChainComplex,List)

For the programmer

The object resLengthThreeTorAlg is a method function.