saturate -- saturation of ideal or submodule

Synopsis

• Usage:

  saturate(I, J)

  saturate I

• Inputs:
  • I, an ideal, a monomial ideal, or a module,
  • J, an ideal, a monomial ideal, a module, or a ring element, if not present, then the ideal generated by the variables of the ring is used
• Optional inputs:
  • Strategy => a thing, default value null, specifies the algorithm
  • MinimalGenerators => a Boolean value, default value true, indicates whether the output should be trimmed
  • BasisElementLimit => ..., default value infinity,
  • DegreeLimit => ..., default value {},
  • PairLimit => ..., default value infinity,
• Outputs:
  • an ideal or a module, the saturation $I:J^\infty = \{f | f J^N\subset I \text{ for some } N>0\}$

Description

i1 : R = ZZ/32003[a..d];

i2 : I = ideal(a^3-b, a^4-c)

             3       4
o2 = ideal (a  - b, a  - c)

o2 : Ideal of R

i3 : Ih = homogenize(I,d)

                        2     2    3      2   3      2
o3 = ideal (a*b - c*d, a c - b d, b  - a*c , a  - b*d )

o3 : Ideal of R

i4 : saturate(Ih,d)

                        2     2    3      2   3      2
o4 = ideal (a*b - c*d, a c - b d, b  - a*c , a  - b*d )

o4 : Ideal of R

i5 : m = ideal vars R

o5 = ideal (a, b, c, d)

o5 : Ideal of R

i6 : M = R^1 / (a * m^2)

o6 = cokernel | a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                            1
o6 : R-module, quotient of R

i7 : M / saturate 0_M

o7 = cokernel | a a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                            1
o7 : R-module, quotient of R

See also

• quotient(Ideal,Ideal)
• annihilator -- the annihilator ideal
• MinimalPrimes -- minimal primes and radical routines for ideals
• PrimaryDecomposition -- primary decomposition and associated primes routines for ideals and modules

Menu

• isSupportedInZeroLocus -- whether support of a module is contained in the zero locus of the (irrelevant) ideal