HH^ZZ(SimplicialComplex,Ring) -- compute the reduced cohomology of an abstract simplicial complex

Synopsis

Function: cohomology
Usage:

cohomology(k, Delta, R)
Inputs:
- k, an integer,
- Delta, an abstract simplicial complex,
- R, a ring, that when omitted is equal to the underlying ring of $\Delta$
Optional inputs:
- Degree => an integer, default value 0, is ignored by this particular function
Outputs:
- a module, that is reduced cohomology group of $\Delta$ with coefficients in $R$

Description

Each abstract simplicial complex $\Delta$ determines a chain complex $\widetilde C(\Delta, k)$ of free modules over its coefficient ring $k$. For all integers $i$, the $i$-th term of $\widetilde C(\Delta, k)$ has a basis corresponding to the $i$-dimensional faces of $\Delta$. The reduced cohomology of $\Delta$ with coefficients in $R$ is, by definition, the cohomology of the chain complex $\operatorname{Hom}( \widetilde C(\Delta, k) \otimes R, R)$.

The 2-sphere has vanishing first cohomology, but non-trivial second cohomology.

i1 : S = ZZ[x_0..x_4];

i2 : Δ = skeleton(2, simplexComplex(3,S));

i3 : prune cohomology(1, Δ)

o3 = 0

o3 : ZZ-module

i4 : prune cohomology(2, Δ)

       1
o4 = ZZ

o4 : ZZ-module, free

A figure eight has rank two first cohomology.

i5 : figureEight = simplicialComplex {x_0*x_1, x_0*x_2, x_1*x_2, x_2*x_3, x_2*x_4, x_3*x_4}

o5 = simplicialComplex | x_3x_4 x_2x_4 x_2x_3 x_1x_2 x_0x_2 x_0x_1 |

o5 : SimplicialComplex

i6 : prune cohomology(1, figureEight)

       2
o6 = ZZ

o6 : ZZ-module, free

Ways to use this method: