algebraicShifting -- the algebraic shifting of a simplicial complex

Synopsis

Usage:

A = algebraicShifting D
Inputs:
- D, an abstract simplicial complex,
Optional inputs:
- Multigrading => a Boolean value, default value false, which, if true, returns the colored algebraic shifting with respect to the multigrading of the underlying ring.
Outputs:
- A, an abstract simplicial complex, which is the algebraic shifting of D. If Multigrading is true, then it returns the so-called colored shifted complex.

Description

The boundary of the stacked 4-polytope on 6 vertices. Algebraic shifting preserves the f-vector.

i1 : R = QQ[x_1..x_6];

i2 : I = monomialIdeal(x_2*x_3*x_4*x_5, x_1*x_6);

o2 : MonomialIdeal of R

i3 : stacked = simplicialComplex I

o3 = simplicialComplex | x_3x_4x_5x_6 x_2x_4x_5x_6 x_2x_3x_5x_6 x_2x_3x_4x_6 x_1x_3x_4x_5 x_1x_2x_4x_5 x_1x_2x_3x_5 x_1x_2x_3x_4 |

o3 : SimplicialComplex

i4 : shifted = algebraicShifting stacked

o4 = simplicialComplex | x_3x_4x_5x_6 x_2x_4x_5x_6 x_1x_4x_5x_6 x_2x_3x_5x_6 x_1x_3x_5x_6 x_2x_3x_4x_6 x_1x_3x_4x_6 x_2x_3x_4x_5 |

o4 : SimplicialComplex

i5 : fVector stacked

o5 = {1, 6, 14, 16, 8}

o5 : List

i6 : fVector shifted

o6 = {1, 6, 14, 16, 8}

o6 : List

An empty triangle is a shifted complex.

i7 : R' = QQ[a,b,c];

i8 : triangle = simplicialComplex {a*b, b*c, a*c}

o8 = simplicialComplex | bc ac ab |

o8 : SimplicialComplex

i9 : algebraicShifting triangle === triangle

o9 = true

The multigraded algebraic shifting does not preserve the Betti numbers.

i10 : grading = {{1,0,0}, {1,0,0}, {1,0,0}, {0,1,0}, {0,0,1}};

i11 : R = QQ[x_{1,1}, x_{1,2}, x_{1,3}, x_{2,1}, x_{3,1}, Degrees => grading];

i12 : delta = simplicialComplex({x_{1,3}*x_{2,1}*x_{3,1}, x_{1,1}*x_{2,1}, x_{1,2}*x_{3,1}})

o12 = simplicialComplex | x_{1, 2}x_{3, 1} x_{1, 1}x_{2, 1} x_{1, 3}x_{2, 1}x_{3, 1} |

o12 : SimplicialComplex

i13 : shifted = algebraicShifting(delta, Multigrading => true)

o13 = simplicialComplex | x_{1, 1} x_{1, 2}x_{3, 1} x_{1, 2}x_{2, 1} x_{1, 3}x_{2, 1}x_{3, 1} |

o13 : SimplicialComplex

i14 : prune (homology(delta))_1

o14 = 0

o14 : QQ-module

i15 : prune (homology(shifted))_1

        1
o15 = QQ

o15 : QQ-module, free

References:

G. Kalai, Algebraic Shifting, Computational Commutative Algebra and Combinatorics, 2001;

S. Murai, Betti numbers of strongly color-stable ideals and squarefree strongly color-stable ideals, Journal of Algebraic Combinatorics.

Ways to use algebraicShifting :

algebraicShifting(SimplicialComplex)

For the programmer

The object algebraicShifting is a method function with options.