inducedSubcomplex(SimplicialComplex,List) -- make the induced simplicial complex on a subset of vertices

Synopsis

Function: inducedSubcomplex
Usage:

inducedSubcomplex(Delta, V)
Inputs:
- Delta, an abstract simplicial complex,
- V, a list, of variables in the ring of $\Delta$ representing vertices
Outputs:
- an abstract simplicial complex, the induced subcomplex of $\Delta$ on the given vertices

Description

Given a simplicial complex $\Delta$ and a subset $V$ of its vertices, the induced subcomplex is the abstract simplicial complexes consisting of all faces in $\Delta$ whose vertices are contained in $V$.

i1 : S = ZZ[x_0..x_3];

i2 : Δ = simplicialComplex{x_0*x_1*x_2, x_2*x_3, x_1*x_3}

o2 = simplicialComplex | x_2x_3 x_1x_3 x_0x_1x_2 |

o2 : SimplicialComplex

i3 : Γ = inducedSubcomplex(Δ, {x_1, x_2, x_3})

o3 = simplicialComplex | x_2x_3 x_1x_3 x_1x_2 |

o3 : SimplicialComplex

i4 : vertices Γ

o4 = {x , x , x }
       1   2   3

o4 : List

i5 : assert (isWellDefined Γ and set vertices Γ === set {x_1, x_2, x_3})

i6 : assert all (facets Γ, F -> member(F, faces(#support F - 1, Δ)))

As a special case, we can consider induced subcomplexes of the void and irrelevant complexes.

i7 : void = simplicialComplex monomialIdeal(1_S);

i8 : inducedSubcomplex(void, {})

o8 = simplicialComplex 0

o8 : SimplicialComplex

i9 : assert(void === inducedSubcomplex(void, {}))

i10 : irrelevant = simplicialComplex {1_S};

i11 : inducedSubcomplex(irrelevant, {})

o11 = simplicialComplex | 1 |

o11 : SimplicialComplex

i12 : assert(irrelevant === inducedSubcomplex(irrelevant, {}))

Ways to use this method: