lyubeznikSimplicialComplex -- create a simplicial complex supporting a Lyubeznik resolution of a monomial ideal

Synopsis

Usage:

lyubeznikSimplicialComplex(L,R)

lyubeznikSimplicialComplex(M,R)
Inputs:
- L, a list, of monomials in a polynomial ring, that minimally generate a monomial ideal.
- M, a monomial ideal,
- R, a polynomial ring, the ambient ring used in constructing the Lyubeznik simplicial complex.
Optional inputs:
- MonomialOrder => a list, default value {}
Outputs:
- D, an abstract simplicial complex,

Description

The Lyubeznik simplicial complex is the simplicial complex that supports the Lyubeznik resolution of an ordered set of monomials. This function is sensitive to the order in which the monomials in $L$ appear. If you are using a monomial ideal $M$ as your input, then the order of the monomials is given by $\operatorname{first} \operatorname{entries} \operatorname{mingens} M$.

i1 : S = QQ[x,y];

i2 : R = QQ[a,b,c];

i3 : M = monomialIdeal{x*y,x^2,y^3};

o3 : MonomialIdeal of S

i4 : D = lyubeznikSimplicialComplex(M,R)

o4 = simplicialComplex | ac ab |

o4 : SimplicialComplex

The lyubeznik resolution of $M$ is the homogenization of $D$ by $M$ (See chainComplex(SimplicialComplex,Labels=>...)).

i5 : L = lyubeznikResolution(M);

i6 : L.dd

          1                    3
o6 = 0 : S  <---------------- S  : 1
               | xy x2 y3 |

          3                      2
     1 : S  <------------------ S  : 2
               {2} | -x -y2 |
               {2} | y  0   |
               {3} | 0  x   |

o6 : ChainComplexMap

i7 : L' = chainComplex(D,Labels=>(first entries mingens M));

i8 : L'.dd

          1                    3
o8 = 0 : S  <---------------- S  : 1
               | xy x2 y3 |

          3                      2
     1 : S  <------------------ S  : 2
               {2} | -x -y2 |
               {2} | y  0   |
               {3} | 0  x   |

o8 : ChainComplexMap

Changing the order of the generators may change the output. We can do this by manually entering the permuted list of generators, or by using the optional $\operatorname{MonomialOrder}$ argument.

i9 : first entries mingens M

            2   3
o9 = {x*y, x , y }

o9 : List

i10 : D' = lyubeznikSimplicialComplex(M,R,MonomialOrder=>{1,2,0})

o10 = simplicialComplex | abc |

o10 : SimplicialComplex

i11 : D' = lyubeznikSimplicialComplex({x^2,y^3,x*y},R)

o11 = simplicialComplex | abc |

o11 : SimplicialComplex

i12 : (lyubeznikResolution(M,MonomialOrder=>{1,2,0})).dd

           1                    3
o12 = 0 : S  <---------------- S  : 1
                | x2 y3 xy |

           3                         3
      1 : S  <--------------------- S  : 2
                {2} | -y3 -y 0  |
                {3} | x2  0  -x |
                {2} | 0   x  y2 |

           3                   1
      2 : S  <--------------- S  : 3
                {5} | 1   |
                {3} | -y2 |
                {4} | x   |

o12 : ChainComplexMap

Ways to use lyubeznikSimplicialComplex :

lyubeznikSimplicialComplex(List,Ring)
lyubeznikSimplicialComplex(MonomialIdeal,Ring)

For the programmer

The object lyubeznikSimplicialComplex is a method function with options.

lyubeznikSimplicialComplex -- create a simplicial complex supporting a Lyubeznik resolution of a monomial ideal

Synopsis

Description

See also

Ways to use lyubeznikSimplicialComplex :

For the programmer