star(SimplicialComplex,RingElement) -- make the star of a face

Synopsis

Function: star
Usage:

star(Delta, F)
Inputs:
- Delta, an abstract simplicial complex,
- F, a ring element, a monomial representing a subset of the vertices in $\Delta$
Outputs:
- an abstract simplicial complex, that consists of all faces in $\Delta$ whose union with $F$ is also a face in $\Delta$

Description

Given a subset $F$ of the vertices in an abstract simplicial complex $\Delta$, the star of $F$ is the set of faces $G$ in $\Delta$ such that the union of $G$ and $F$ is also a face in $\Delta$. This set forms a subcomplex of $\Delta$. When the subset $F$ is not face in $\Delta$, the star of $F$ is a void complex (having no facets).

The star of a subset $F$ may be the entire complex, a proper subcomplex, or the void complex.

i1 : S = ZZ[a..e];

i2 : Δ = simplicialComplex {a*b*c, c*d*e}

o2 = simplicialComplex | cde abc |

o2 : SimplicialComplex

i3 : star (Δ, c)

o3 = simplicialComplex | cde abc |

o3 : SimplicialComplex

i4 : assert (star (Δ, c) === Δ)

i5 : star (Δ, a*b)

o5 = simplicialComplex | abc |

o5 : SimplicialComplex

i6 : assert (star (Δ, a*b) === simplicialComplex {a*b*c})

i7 : star (Δ, a*d)

o7 = simplicialComplex 0

o7 : SimplicialComplex

i8 : assert (star (Δ, a*d) === simplicialComplex monomialIdeal 1_S)

Ways to use this method: