specialGushelMukaiFourfold(Array,Array,String,Thing) -- construct GM fourfolds by gluing cubic or quartic scrolls to surfaces in PP^6

Synopsis

Function: specialGushelMukaiFourfold
Usage:

specialGushelMukaiFourfold(surface,curve)

specialGushelMukaiFourfold(surface,curve,scroll)

specialGushelMukaiFourfold(surface,curve,K)

specialGushelMukaiFourfold(surface,curve,scroll,K)
Inputs:
- surface, an array, an array of integers [a,i,j,k,...] to indicate the rational surface $S\subset\mathbb{P}^6$ constructed by surface({a,i,j,k,...},K,ambient=>6)
- curve, an array, an array of integers [d,l,m,n,...] to indicate the plane representation of a curve $C$ on the surface $S$ (the command that constructs $C$ is S.cache#"takeCurve"(d,{l,m,n,...}))
- scroll, a string, which can be either "cubic scroll" (the default value) or "quartic scroll", to indicate the type of scroll $B\subset\mathbb{P}^6$ to be used; in the former case $B\simeq\mathbb{P}^1\times\mathbb{P}^2\subset\mathbb{P}^5\subset\mathbb{P}^6$ while in the latter case $B\subset\mathbb{P}^6$ is a generic projection of a rational normal quartic scroll of dimension 4 in $\mathbb{P}^7$
- K, a thing, the coefficient ring (ZZ/65521 is used by default)
Optional inputs:
- InputCheck => ..., default value 1, make a special Gushel-Mukai fourfold
- Verbose => ..., default value false, request verbose feedback
Outputs:
- a special Gushel-Mukai fourfold, a GM fourfold $X$ containing the surface $\overline{\psi_{B}(S)}\subset\mathbb{G}(1,4)\subset\mathbb{P}^9$, where $B$ is a scroll of the indicated type such that $C\subseteq S\cap B$ and $\psi_{B}:\mathbb{P}^6\dashrightarrow\mathbb{G}(1,4)$ is the birational map defined by $B$

Description

From the returned fourfold $X$, with the following commands we obtain the surface $S$, the curve $C$, and the scroll $B$ used in the construction:

(B,C) = X.cache#"Construction"; S = ambientVariety C;

Then the surface $\overline{\psi_{B}(S)}\subset\mathbb{G}(1,4)$ can be constructed with

psi = rationalMap B; (psi S)%(image psi);

In the following example we construct a GM fourfold containing the image via $\psi_B:\mathbb{P}^6\dashrightarrow\mathbb{G}(1,4)$ of a quintic del Pezzo surface $S\subset\mathbb{P}^5\subset\mathbb{P}^6$, obtained as the image of the plane via the linear system of quartic curves with three general simple base points and two general double points, which cuts $B\simeq\mathbb{P}^1\times\mathbb{P}^2\subset\mathbb{P}^5\subset\mathbb{P}^6$ along a rational normal quartic curve obtained as the image of a general conic passing through the two double points.

i1 : X = specialGushelMukaiFourfold([4, 3, 2],[2, 0, 2]);

o1 : ProjectiveVariety, GM fourfold containing a surface of degree 6 and sectional genus 1

i2 : describe X

o2 = Special Gushel-Mukai fourfold of discriminant 18(')
     containing a surface in PP^8 of degree 6 and sectional genus 1
     cut out by 11 hypersurfaces of degrees (1,1,2,2,2,2,2,2,2,2,2)
     and with class in G(1,4) given by 3*s_(3,1)+3*s_(2,2)
     Type: ordinary

i3 : (B,C) = X.cache#"Construction";

i4 : S = ambientVariety C;

o4 : ProjectiveVariety, surface in PP^6

i5 : C;

o5 : ProjectiveVariety, curve in PP^6 (subvariety of codimension 1 in S)

i6 : B;

o6 : ProjectiveVariety, threefold in PP^6

i7 : assert(C == S * B)

References

G. Staglianò, Explicit computations with cubic fourfolds, Gushel-Mukai fourfolds, and their associated K3 surfaces, available at arXiv:2204.11518 (2022).

Ways to use this method: