lowerCorner -- compute the lower corner

Synopsis

Usage:

m=lowerCorner(F,d)
Inputs:
- F, a chain complex, over the exterior algebra
- d, a list, a (multi)-degree
Outputs:
- a matrix, a submatrix of the differential $F_{k+1} -> F_{k}$

Description

Let $k = |deg|$ be the total degree and $G \subset F_k$ the summand spanned by the generators of $F_k$ in degree d, $H \subset F_{k+1}$ the summand spanned by generators of degree d' with $0 \le d-d' \le n$. The function returns the corresponding submatrix $m: H -> G$ of the differential.

i1 : n={1,2};

i2 : (S,E) = productOfProjectiveSpaces n

o2 = (S, E)

o2 : Sequence

i3 : F=dual res((ker transpose vars E)**E^{{ 2,3}},LengthLimit=>4)

      70      35      15      5      1
o3 = E   <-- E   <-- E   <-- E  <-- E
                                     
     -4      -3      -2      -1     0

o3 : ChainComplex

i4 : betti F

            -4 -3 -2 -1 0
o4 = total: 70 35 15  5 1
         0: 70 35 15  5 1

o4 : BettiTally

i5 : tallyDegrees F

o5 = (Tally{{-1, -3} => 20}, Tally{{-1, -2} => 12}, Tally{{-1, -1} => 6},
            {-2, -2} => 18         {-2, -1} => 9          {-2, 0} => 3   
            {-3, -1} => 12         {-3, 0} => 4           {0, -2} => 6
            {-4, 0} => 5           {0, -3} => 10
            {0, -4} => 15
     ------------------------------------------------------------------------
     Tally{{-1, 0} => 2}, Tally{{0, 0} => 1})
           {0, -1} => 3

o5 : Sequence

i6 : deg={2,1}

o6 = {2, 1}

o6 : List

i7 : m=lowerCorner(F,deg);

             9      9
o7 : Matrix E  <-- E

i8 : tally degrees target m, tally degrees source m

o8 = (Tally{{-2, -1} => 9}, Tally{{-1, -1} => 6})
                                  {-2, 0} => 3

o8 : Sequence

i9 : Fm=(res(coker m,LengthLimit=>7))[sum deg]

      9      9      8      15      32      57      91      137
o9 = E  <-- E  <-- E  <-- E   <-- E   <-- E   <-- E   <-- E
                                                           
     -3     -2     -1     0       1       2       3       4

o9 : ChainComplex

i10 : betti Fm

             -3 -2 -1  0  1  2  3   4
o10 = total:  9  9  8 15 32 57 91 137
          0:  9  9  5  1  .  .  .   .
          1:  .  .  .  3  7 11 15  19
          2:  .  .  3 11 25 45 71 103
          3:  .  .  .  .  .  1  5  15

o10 : BettiTally

i11 : cohomologyMatrix(Fm,-{3,3},{4,4})

o11 = | 0   0  0 0  0   0   0 0 |
      | 0   0  0 0  0   0   0 0 |
      | 0   0  0 0  0   0   0 0 |
      | 6h  3h 0 3  6   9   0 0 |
      | 2h  h  0 1  2   3   0 0 |
      | 0   0  0 0  0   0   0 0 |
      | 0   0  0 0  0   0   0 0 |
      | 2h3 h3 0 h2 2h2 3h2 0 0 |

                       8               8
o11 : Matrix (ZZ[h, k])  <-- (ZZ[h, k])

Ways to use lowerCorner :

lowerCorner(ChainComplex,List)

For the programmer

The object lowerCorner is a method function.