terraciniLocus -- compute the Terracini locus of a projective variety

Synopsis

Usage:

terraciniLocus(r, X)
Inputs:
- r, an integer,
- X, a ring map or an ideal,
Optional inputs:
- Threads => an integer, default value 0, the number of threads used during the computation. This option is passed to recursiveMinors.
Outputs:
- an ideal,

Description

There are two methods to compute the Terracini locus of a projective variety.

First, consider a rational variety parametrized by a polynomial map $f:\mathbb P^n\dashrightarrow\mathbb P^m$. In Macaulay2, this may be represented using a RingMap object from the coordinate ring of $\mathbb P^m$ to the coordinate ring of $\mathbb P^n$. We consider the twisted cubic in $\mathbb P^3$.

i1 : R = QQ[s,t]

o1 = R

o1 : PolynomialRing

i2 : S = QQ[x_0..x_3]

o2 = S

o2 : PolynomialRing

i3 : f = map(R, S, {s^3, s^2*t, s*t^2, t^3})

                  3   2      2   3
o3 = map (R, S, {s , s t, s*t , t })

o3 : RingMap R <-- S

In this case, the ideal of the preimage of the Terracini locus in $(\mathbb P^n)^r$ is returned. So in our twisted cubic example, if $r=2$, then we get the ideal of the pairs of points in $\mathbb P^1\times\mathbb P^1$ whose images under $f$ belong to the 2nd Terracini locus.

i4 : terraciniLocus(2, f)

o4 = ideal 1

o4 : Ideal of QQ[z   ..z   ]
                  0,0   1,1

We see that the Terracini locus is empty, which is true for all rational normal curves.

We may also consider varieties in $\mathbb P^n$ defined by an ideal. Let us continue with the twisted cubic example.

i5 : I = ker f

             2                       2
o5 = ideal (x  - x x , x x  - x x , x  - x x )
             2    1 3   1 2    0 3   1    0 2

o5 : Ideal of S

In this case, we may only use $r=2$. The ideal of the pairs of points in $\mathbb P^n\times\mathbb P^n$ belonging to the Terracini locus is returned. So for the twisted cubic, we get an ideal in the coordinate ring of $\mathbb P^3\times\mathbb P^3$.

i6 : terraciniLocus(2, I)

o6 = ideal 1

o6 : Ideal of QQ[z   ..z   ]
                  0,0   1,3

For more examples, see https://github.com/d-torrance/terracini-loci.

Ways to use terraciniLocus :

terraciniLocus(ZZ,Ideal)
terraciniLocus(ZZ,Matrix,Ideal)
terraciniLocus(ZZ,RingMap)

For the programmer

The object terraciniLocus is a method function with options.