triangulation -- make a Triangulation object

Synopsis

Usage:

triangulation(A, T)
Inputs:
- A, a matrix,
- T, a list, representing a triangulation of the columns of $A$ (each element in the list is a list of indices in the range $0, \ldots, n-1$, where $n$ is the number of columns of $A$)
Optional inputs:
- Homogenize (missing documentation) => a Boolean value, default value true, if true, add a row of ones to think of this as a vector configuration in one higher dimension.
Outputs:
- an instance of the type Triangulation (missing documentation) , A Triangulation (missing documentation) object. Very little computation is performed. The matrix and list representing a triangulation is packaged into an object to make clear that it is a triangulation

Description

i1 : P = hypercube 3

o1 = P

o1 : Polyhedron

i2 : A = vertices P

o2 = | -1 1  -1 1  -1 1  -1 1 |
     | -1 -1 1  1  -1 -1 1  1 |
     | -1 -1 -1 -1 1  1  1  1 |

              3       8
o2 : Matrix QQ  <-- QQ

i3 : T = topcomRegularFineTriangulation A

o3 = {{0, 1, 2, 4}, {1, 2, 3, 4}, {1, 3, 4, 5}, {2, 3, 4, 6}, {3, 4, 5, 6},
     ------------------------------------------------------------------------
     {3, 5, 6, 7}}

o3 : List

i4 : tri = triangulation(A, T)

o4 = triangulation {{0, 1, 2, 4}, {1, 2, 3, 4}, {1, 3, 4, 5}, {2, 3, 4, 6}, {3, 4, 5, 6}, {3, 5, 6, 7}}

o4 : Triangulation

i5 : matrix tri

o5 = | -1 1  -1 1  -1 1  -1 1 |
     | -1 -1 1  1  -1 -1 1  1 |
     | -1 -1 -1 -1 1  1  1  1 |
     | 1  1  1  1  1  1  1  1 |

              4       8
o5 : Matrix QQ  <-- QQ

i6 : vectors tri

o6 = {{-1, -1, -1, 1}, {1, -1, -1, 1}, {-1, 1, -1, 1}, {1, 1, -1, 1}, {-1,
     ------------------------------------------------------------------------
     -1, 1, 1}, {1, -1, 1, 1}, {-1, 1, 1, 1}, {1, 1, 1, 1}}

o6 : List

i7 : max tri

o7 = {{0, 1, 2, 4}, {1, 2, 3, 4}, {1, 3, 4, 5}, {2, 3, 4, 6}, {3, 4, 5, 6},
     ------------------------------------------------------------------------
     {3, 5, 6, 7}}

o7 : List

i8 : isWellDefined tri

o8 = true

i9 : netList affineCircuits tri

     +------+------+
o9 = |{1, 2}|{0, 3}|
     +------+------+
     |{3, 4}|{2, 5}|
     +------+------+
     |{3, 4}|{1, 6}|
     +------+------+
     |{5, 6}|{4, 7}|
     +------+------+

i10 : isFine tri

o10 = true

i11 : isStar tri

o11 = false

i12 : isRegularTriangulation tri

o12 = true

triangulation -- make a Triangulation object

Synopsis

Description

Caveat

See also

Ways to use triangulation :

For the programmer