Ordered modules -- Overview of the ordered module $\QQ^n$

Many standard valuations take values in a totally ordered subgroup $\Gamma \subseteq \QQ^n$. These standard valuations implement an instance of the type OrderedQQn, whose order is based on the monomial order of a given ring $R$. The values in $\QQ^n$ are compared using the monomial order of $R$. By default, our valuations use the min convention, that is $v(a + b) \ge \min(v(a), v(b))$.

i1 : R = QQ[x,y];

i2 : I = ideal(x,y);

o2 : Ideal of R

i3 : v = leadTermValuation R;

i4 : a = v(x)

o4 = | -1 |
     |  0 |

o4 : Ordered QQ^2 module

i5 : b = v(y)

o5 = |  0 |
     | -1 |

o5 : Ordered QQ^2 module

i6 : c = v(x+y)

o6 = | -1 |
     |  0 |

o6 : Ordered QQ^2 module

i7 : a > b

o7 = false

i8 : a == c

o8 = true

Two ordered $\QQ^n$ modules are equal if they are built from the same ring. Note that isomorphic rings with the same term order may not be equal.

i9 : M1 = orderedQQn(3, {Lex})

       3
o9 = QQ

o9 : Ordered QQ^3 module

i10 : R = M1.cache.Ring

o10 = R

o10 : PolynomialRing

i11 : M2 = orderedQQn R

        3
o11 = QQ

o11 : Ordered QQ^3 module

i12 : M1 == M2

o12 = true

i13 : S = QQ[x_1 .. x_3, MonomialOrder => {Lex}]
warning: clearing value of symbol x to allow access to subscripted variables based on it
       : debug with expression   debug 9868   or with command line option   --debug 9868

o13 = S

o13 : PolynomialRing

i14 : M3 = orderedQQn S

        3
o14 = QQ

o14 : Ordered QQ^3 module

i15 : M1 == M3

o15 = false

Ordered modules -- Overview of the ordered module $\QQ^n$

See also